Jürgen,
This message is being resent because last minute changes I made
to CRS0.apl and CRS1.apl do not output thedata I intended. This
message has corrected versions of those files attached. Please discard
the old CRS0.apl and CRS1.apl files. The first line of output is the
modulo basis, the second line is the calculated complete residue system
values and the third line is the number of residues in the CRS on the
previous line.
CRSOTST0.apl and CRSOTST1.apl are unchanged.
Also please find attached MOD_TEST.apl which compares the
residues calculated by MODJ and the builtin residue function and
reports discrepancies. The first column of output is the modulo basis,
the second column the right argument to the functions, the third column
the MODJ result and the fourth column is the builtin residue function
result.
Regards
Fred
Hello Jürgen,
SVN 964 moved us in the right direction but not completely out
of thewoods. SVN 964 still exhibits errors. For instance
2J6 | 5J5¯1J7 2J6 | ¯1J7¯3J1 2J6 | ¯3J1¯3J1
I found this and previous residue function errors using the
attached APLcode files. The files with base name ending in '0' use the
builtin residuefunction. Those with base name ending in '1' use a
residue function implementedin APL. The files with base name beginning
with 'CRSOTST' test if the order ofthe complete residue system (CRS)
equals the norm of the modulo basis. Thattest fails for several modulo
bases, 2J6 being one of them, using the builtinresidue function. No
errors are detected with the APL implementation. The other filescan be
used to plot the CRS for a given modulo basis where 'a' and 'b' in'a +
b * i' are limited to +15 to -15 range. A full screen terminal window
isneeded to see the plot.
My APL implementation of the residue function is very close to
what youdescribed in your previous email. Maybe comparing the two
implementations willgive insight into why the builtin residue function
fails for some modulo bases.
I make no assertion that my implementation is correct in
allaspects.
Regards,
Fred
On Tue, 2017-06-20 at 14:14 +0200, Juergen Sauermann wrote:
> Hi Frederick,
>
>
>
> the algorithm for A ∣ B used in GNU APL is this:
>
>
>
> - compute the
> quotient Q←B÷A,
>
> - "round down" Q to the next (complex) integer Q1,
>
> - return B - Q1×A
>
>
>
> Now the problem seems to be what is meant by "round down".
> There
> are two candidates:
>
>
>
> Q1 ← ⌊
> Q i.e. use APL
> floor
> to round down Q
>
> Q1 ← Complex( floor(Q.real(), floor(Q.imag()) ) i,e,
> use C/C++ floor() to round down Q.
>
>
>
> In your 5J3 ∣ 14J5 example, the quotient is 2.5J¯0.5,
> which gives different results for the APL floor ⌊ and the
> C/C++ floor().
>
>
>
> The APL floor ⌊2.5J¯0.5
> is 3J¯1
> (a somewhat dubious invention in the ISO standard on page 19,
> which I used up to
>
> including SVN 963), while the C/C++ floor() is
> 2J¯1. The difference between the APL floor
> and the C/C++ floor is 1.0 which,
>
> multiplied by the divisor, explains the differences that we
> see.
>
>
>
> As of SVN 964 I have changed the residue function (∣)
> to use the C/C++ floor instead of the APL floor. The APL floor
> and
>
> Ceiling functions (⌊ and ⌈) are still using the
> apparently broken definition in the ISO standard.
>
>
>
> I hope this works better for you. At least I am getting this in
> SVN
> 964:
>
>
>
> 5J3 | 14J5
>
> 1J4
>
> 5J3 | 1J4
>
> 1J4
>
>
>
> whereas SVN 963 was giving:
>
>
>
> 5J3 | 14J5
>
> ¯4J1
>
> 5J3 | 1J4
>
> ¯4J1
>
>
>
>
>
> Best Regards,
>
> /// Jürgen
>
>
>
>
>
>
>
> On 06/19/2017 07:03 PM, Frederick Pitts
> wrote:
>
>
>
> > Jürgen,
> >
> > With gnu apl (svn 961 on Fedora 25, Intel(R) Core(TM) i7-6700
> > CPU), the residue function (∣) yields the following:
> >
> > 5J3 ∣ 14J5
> > 1J4
> > 5J3 | 1J4
> > ¯4J1
> > 5J3 | ¯4J1
> > ¯4J1
> > The above result means that two elements in the complete residue
> > system
> > (CSR) for mod 5J3 are equal, i.e. 1J4 = ¯4J1 mod 5J3, which is not
> > allowed. None of the elements of a CSR can be equal modulo the
> > CSR's
> > basis.
> >
> > Regards,
> >
> > Fred
> >
> >
> >
>
>
>
>
> ⎕pw ← 195
∇ z ← NORMJ m
z ← m × + m
∇
∇ z ← SUE v
z ← ( ( v ⍳ v ) = ⍳ ⍴ v ) / v
∇
∇ z ← CRSOTST alpha; crsbi; crsbiu; ordbiu; nrm
z ← 0
→ ( 0 = alpha ) / 0
ordbiu ← ⍴ crsbiu ← SUE crsbi ← , alpha ∣ betav
nrm ← NORMJ alpha
→ ( z ← ordbiu = nrm ) / 0
⍞ ← "modulo basis = "
⍞ ← alpha
⍞ ← " basis norm = "
⍞ ← nrm
⍞ ← " residue count = "
⍞ ← ordbiu
""
∇
bgn ← ¯16
rng ← 31
dmn ← bgn + ⍳ rng
betav ← , beta ← dmn ∘.+ 0J1 × dmn
" "
rng rng ⍴ CRSOTST ¨ betav
⎕pw ← 195
⍝ The square root of ¯1, a pure imaginary number.
⍙J ← 0J1
⍝ CMPLX is an array function.
∇ z ← m CMPLX n
z ← m + ⍙J × n
∇
⍝ CMPLX0 is a scalar function.
∇ z ← CMPLX0 a; m; n
( m n ) ← a
z ← m + ⍙J × n
∇
⍝ Euclidean division algorithm for Gaussian integers.
⍝ DIVJ is a scalar function.
∇ z ← a DIVJ b; q; r
→ ( b ≠ 0J0 ) / L0
z ← 0 a
→ 0
L0:
r ← a - b × q ← CMPLX0 ⌊ ( 9 11 ) ○ a ÷ b
z ← q , r
∇
⍝ Modulo function for Gaussian integers. A test replacement for current
⍝ gnu-apl ∣ function applied to Gaussian integers.
⍝ MODJ is a scalar function.
∇ z ← a MODJ b
z ← ↑ ¯1 ↑ b DIVJ a
∇
∇ z ← NORMJ m
z ← m × + m
∇
∇ z ← SUE v
z ← ( ( v ⍳ v ) = ⍳ ⍴ v ) / v
∇
∇ z ← CRSOTST alpha; crsed; crsedu; ordedu; crsbi; crsbiu; ordbiu; nrm
z ← 0
→ ( 0 = alpha ) / 0
ordedu ← ⍴ crsedu ← SUE crsed ← , alpha MODJ ¨ betav
nrm ← NORMJ alpha
→ ( z ← ordedu = nrm ) / 0
⍞ ← "modulo basis = "
⍞ ← alpha
⍞ ← " basis norm = "
⍞ ← nrm
⍞ ← " residue count = "
⍞ ← orded
""
∇
bgn ← ¯16
rng ← 31
dmn ← bgn + ⍳ rng
betav ← , beta ← dmn ∘.+ 0J1 × dmn
" "
rng rng ⍴ CRSOTST ¨ betav
⎕pw ← 95
⍝ The square root of ¯1, a pure imaginary number.
⍙J ← 0J1
⍝ CMPLX is an array function.
∇ z ← m CMPLX n
z ← m + ⍙J × n
∇
⍝ CMPLX0 is a scalar function.
∇ z ← CMPLX0 a; m; n
( m n ) ← a
z ← m + ⍙J × n
∇
⍝ Euclidean division algorithm for Gaussian integers.
⍝ DIVJ is a scalar function.
∇ z ← a DIVJ b; q
→ ( b ≠ 0J0 ) / L0
z ← 0 a
→ 0
L0:
z ← q , a - b × q ← CMPLX0 ⌊ ( 9 11 ) ○ a ÷ b
∇
⍝ Modulo function for Gaussian integers. A test replacement for current
⍝ gnu-apl ∣ function applied to Gaussian integers.
⍝ MODJ is a scalar function.
∇ z ← a MODJ b
z ← ↑ ¯1 ↑ b DIVJ a
∇
∇ z ← NORMJ m
z ← m × + m
∇
∇ z ← SUE v
z ← ( ( v ⍳ v ) = ⍳ ⍴ v ) / v
∇
∇ PLOT; ia; ra; bg; dmn; crs; unq; crsr; crsi; n; i
ia ← 32 1 ⍴ ( 15 ⍴ ' ' ) , '-' , 16 ⍴ ' '
ra ← ( 45 ⍴ ' ' ) , ' | ' , 45 ⍴ ' '
bg ← ia , ( 31 93 ⍴ ' ∘ ' ) ,[ 1 ] ra
bgn ← ¯16
rng ← 31
dmn ← bgn + ⍳ rng
beta ← dmn ∘.+ 0J1 × dmn
crs ← , ( ⎕ ← 2J6 ) ∣ beta
unq ← ( crs ⍳ crs ) = ⍳ ⍴ crs
⎕ ← ⍴ ⎕ ← ucrs ← unq / crs
crsr ← 9 ○ ucrs
crsr ← 3 × 16 + crsr
crsi ← 11 ○ ucrs
crsi ← 16 + crsi
n ← ⍴ crsr
i ← 0
L0:
→ ( i ≥ n ) / L1
i ← i + 1
bg[ crsi[ i ] ; crsr[ i ] ] ← '⎕'
→ L0
L1:
" "
⊖bg
∇
PLOT
⎕pw ← 95
⍝ The square root of ¯1, a pure imaginary number.
⍙J ← 0J1
⍝ CMPLX is an array function.
∇ z ← m CMPLX n
z ← m + ⍙J × n
∇
⍝ CMPLX0 is a scalar function.
∇ z ← CMPLX0 a; m; n
( m n ) ← a
z ← m + ⍙J × n
∇
⍝ Euclidean division algorithm for Gaussian integers.
⍝ DIVJ is a scalar function.
∇ z ← a DIVJ b; q
→ ( b ≠ 0J0 ) / L0
z ← 0 a
→ 0
L0:
z ← q , a - b × q ← CMPLX0 ⌊ ( 9 11 ) ○ a ÷ b
∇
⍝ Modulo function for Gaussian integers. A test replacement for current
⍝ gnu-apl ∣ function applied to Gaussian integers.
⍝ MODJ is a scalar function.
∇ z ← a MODJ b
z ← ↑ ¯1 ↑ b DIVJ a
∇
∇ z ← NORMJ m
z ← m × + m
∇
∇ z ← SUE v
z ← ( ( v ⍳ v ) = ⍳ ⍴ v ) / v
∇
∇ PLOT; ia; ra; bg; dmn; crs; unq; crsr; crsi; n; i
ia ← 32 1 ⍴ ( 15 ⍴ ' ' ) , '-' , 16 ⍴ ' '
ra ← ( 45 ⍴ ' ' ) , ' | ' , 45 ⍴ ' '
bg ← ia , ( 31 93 ⍴ ' ∘ ' ) ,[ 1 ] ra
bgn ← ¯16
rng ← 31
dmn ← bgn + ⍳ rng
beta ← dmn ∘.+ 0J1 × dmn
crs ← , ( ⎕ ← 2J6 ) MODJ ¨ beta
unq ← ( crs ⍳ crs ) = ⍳ ⍴ crs
⎕ ← ⍴ ⎕ ← ucrs ← unq / crs
crsr ← 9 ○ ucrs
crsr ← 3 × 16 + crsr
crsi ← 11 ○ ucrs
crsi ← 16 + crsi
n ← ⍴ crsr
i ← 0
L0:
→ ( i ≥ n ) / L1
i ← i + 1
bg[ crsi[ i ] ; crsr[ i ] ] ← '⎕'
→ L0
L1:
" "
⊖bg
∇
PLOT
#!/usr/local/bin/apl --script
⍝ Run with: ./MOD_TEST.apl
⍝ !!! This test is totally bogus because the residues produced by MODJ and ∣ for
⍝ a given modulo basis belong to different complete residue classes. !!!
pwold ← ⎕pw
⎕pw ← 196
∇ CONT
""
⍞ ← "Press enter to continue..."
⍞
""
∇
∇ EXIT
""
⍞ ← "Press enter to exit..."
⍞
∇
∇ z ← rcl LABEL tbl
z ← ⍉ ⌽ ( ⌽ ⍉ ¯1 ⌽ tbl , 1 ⊃ rcl ) , ¯99J¯99, 2 ⊃ rcl
∇
∇ z ← NORMJ m
z ← m × + m
∇
⍝ Truncate toward negative infinity.
⍝ This is an array function.
∇z ← ROUND x
z ← ⌊ x
∇
⍙J ← 0J1
∇ z ← CMPLX a; m; n
( m n ) ← a
z ← m + ⍙J × n
∇
∇ z ← m CMPLX0 n
z ← m + ⍙J × n
∇
∇ z ← ROUNDJ m
z ← CMPLX0 / ROUND 9 11 ○ m
∇
⍝ Euclidean division algorithm for Gaussian integers.
⍝ DIVJ is a scalar function.
∇ z ← a DIVJ b; q
→ ( b ≠ 0J0 ) / L0
z ← 0 a
→ 0
L0:
z ← q , a - b × q ← CMPLX ⌊ ( 9 11 ) ○ a ÷ b
∇
⍝ Modulo function for Gaussian integers. A test replacement for current
⍝ gnu-apl ∣ function applied to Gaussian integers.
⍝ MODJ is a scalar function.
∇ z ← a MODJ b
z ← ¯1 ↑ b DIVJ a
∇
∇REPORT; n; r; c; rsd0; rsd1; bad; cnt; cl; clr
⍝ Test is performed on a grid of complex numbers ranging from ¯nJ¯n in the
⍝ lower left corner to nJn in the upper right corner.
n ← 6 ⍝ 50
n2p1 ← 1 + 2 × n
⍝ r is a vector of Gaussian integer real parts
r ← ( ¯1 - n ) + ⍳ n2p1
⍝ c is a vector of all the required Gaussian integers generated from r.
c ← , r ∘.+ 0J1 × r
⍝ rsd0 is matrix of residue's for all possible pairings of the elements of
⍝ c using MODJ.
rsd0 ← , ⊃ c ∘.MODJ c
⍝ rsd1 is matrix of residue's for all possible pairings of the elements of c
⍝ using APL mod operator (∣).
rsd1 ← , ⊃ c ∘.∣ c
⍝ colarg is a ( n2p1 ⋆ 2 ) ⋆ 2 vector composed of the c vector repeated
⍝ n2p1 ⋆ 3 times.
colarg ← ( ( n2p1 ⋆ 2 ) ⋆ 2 ) ⍴ c
⍝ rowarg is a ( n2p1 ⋆ 2 ) ⋆ 2 vector composed of the c vector elements
⍝ repeated n2p1 ⋆ 2 times each.
rowarg ← ( ( n2p1 ⋆ 2 ) ⍴ n2p1 ⋆ 2 ) / c
" "
⍝ Compare rsd0 and rsd1 to determine if there are discrepancies.
bad ← rsd0 ≠ rsd1
⍝ Count the bad elements and return if cnt is zero.
→ ( 0 = cnt ← + / bad ) / 0
⍝ Otherwise, generate a table of the arguments and differing results
' LA RA MODJ |'
d ← cnt 1
( d ⍴ bad / , rowarg ) , ( d ⍴ bad / , colarg ) , ( d ⍴ bad / rsd0 ) , d ⍴
bad / rsd1
∇
REPORT
"FINISHED"
