I realize the patch is not very readable. Sorry about this, here are
the most interesting differences:
BEFORE:
< # AC_CANONICALIZE(THING)
< # ----------------------
< # Canonicalize the appropriate THING, generating the variables THING,
< # THING_{alias cpu vendor os}, and the associated cache entries.
< AC_DEFUN([AC_CANONICALIZE],
< [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
< ac_cv_$1=`$ac_config_sub $ac_cv_$1_alias` || exit 1
< ac_cv_$1_cpu=`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\1/'`
< ac_cv_$1_vendor=`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\2/'`
< ac_cv_$1_os=`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\3/'`
< AC_SUBST([$1], [$ac_cv_$1])dnl
< AC_SUBST([$1_alias], [$ac_cv_$1_alias])dnl
< AC_SUBST([$1_cpu], [$ac_cv_$1_cpu])dnl
< AC_SUBST([$1_vendor], [$ac_cv_$1_vendor])dnl
< AC_SUBST([$1_os], [$ac_cv_$1_os])dnl
< ])# AC_CANONICALIZE
<
<
< # _AC_CANONICAL_THING(THING)
< # --------------------------
< # Worker routine for AC_CANONICAL_SYSTEM. THING is one of `host',
< # `target', or `build'. Canonicalize the appropriate thing. We also
< # redo the cache entries if the user specifies something different
< # from ac_cv_$THING_alias on the command line.
< define([_AC_CANONICAL_THING],
< [AC_MSG_CHECKING([$1 system type])
< if test "x$ac_cv_$1" = "x" ||
< (test "x$$1" != "x" && test "x$$1" != "x$ac_cv_$1_alias"); then
<
< dnl Set $1_alias.
< ac_cv_$1_alias=$$1
< test "x$ac_cv_$1_alias" = "x" &&
< m4_case([$1],
< [build],
< [{ ac_cv_build_alias=`$ac_config_guess` ||
< AC_MSG_ERROR(
< [cannot guess build (this machine) type; you must specify one]); }],
< [host],
< [ac_cv_host_alias=$build_alias],
< [target],
< [ac_cv_target_alias=$host_alias])
< else
< echo $ECHO_N "(cached) $ECHO_C" >&AC_FD_MSG
< fi
< AC_CANONICALIZE([$1])
< AC_MSG_RESULT($ac_cv_$1)[]dnl
< ])# _AC_CANONICAL_THING
<
<
< # AC_CANONICAL_BUILD
< # ------------------
< AC_DEFUN_ONCE([AC_CANONICAL_BUILD],
< [AC_DIVERT([HELP_CANON],
< [[
< Hosts type:
< --build=BUILD configure for building on BUILD [guessed]]])dnl
< # Make sure we can run config.sub.
< $ac_config_sub sun4 >/dev/null 2>&1 ||
< AC_MSG_ERROR([cannot run $ac_config_sub])
<
< _AC_CANONICAL_THING(build)[]dnl
< ])# AC_CANONICAL_BUILD
<
<
< # AC_CANONICAL_HOST
< # -----------------
< AC_DEFUN_ONCE([AC_CANONICAL_HOST],
< [AC_REQUIRE([AC_CANONICAL_BUILD])dnl
< AC_DIVERT([HELP_CANON],
< [[ --host=HOST cross-compile to build programs running on HOST [BUILD]]])dnl
< _AC_CANONICAL_THING(host)[]dnl
< ])# AC_CANONICAL_HOST
<
<
< # AC_CANONICAL_TARGET
< # -------------------
< AC_DEFUN_ONCE([AC_CANONICAL_TARGET],
< [AC_REQUIRE([AC_CANONICAL_HOST])dnl
< AC_BEFORE([$0], [AC_ARG_PROGRAM])dnl
< AC_DIVERT([HELP_CANON],
< [[ --target=TARGET configure for building compilers for TARGET [HOST]]])dnl
< _AC_CANONICAL_THING(target)[]dnl
<
< # The aliases save the names the user supplied, while $host etc.
< # will get canonicalized.
< test "$host_alias" != "$target_alias" &&
< test "$program_prefix$program_suffix$program_transform_name" = \
< NONENONEs,x,x, &&
< program_prefix=${target_alias}-[]dnl
< ])# AC_CANONICAL_TARGET
AFTER
> # _AC_CANONICAL_SPLIT(THING)
> # --------------------------
> # Generate the variables THING, THING_{alias cpu vendor os}.
> AC_DEFUN([_AC_CANONICAL_SPLIT],
> [AC_SUBST([$1], [$ac_cv_$1])dnl
> dnl FIXME: AC_SUBST([$1_alias], [$ac_cv_$1_alias])dnl
> AC_SUBST([$1_cpu],
> [`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\1/'`])dnl
> AC_SUBST([$1_vendor],
> [`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\2/'`])dnl
> AC_SUBST([$1_os],
> [`echo $ac_cv_$1 | sed 's/^\([[^-]]*\)-\([[^-]]*\)-\(.*\)$/\3/'`])dnl
> ])# _AC_CANONICAL_SPLIT
>
>
> # AC_CANONICAL_BUILD
> # ------------------
> AC_DEFUN_ONCE([AC_CANONICAL_BUILD],
> [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
> AC_DIVERT([HELP_CANON],
> [[
> Hosts type:
> --build=BUILD configure for building on BUILD [guessed]]])dnl
> # Make sure we can run config.sub.
> $ac_config_sub sun4 >/dev/null 2>&1 ||
> AC_MSG_ERROR([cannot run $ac_config_sub])
>
> AC_CACHE_CHECK([build system type], [ac_cv_build],
> [ac_cv_build_alias=$build_alias
> test -z "$ac_cv_build_alias" &&
> ac_cv_build_alias=`$ac_config_guess`
> test -z "$ac_cv_build_alias" &&
> AC_MSG_ERROR([cannot guess build type; you must specify one])
> ac_cv_build=`$ac_config_sub $ac_cv_build_alias` || exit 1
> ])
> _AC_CANONICAL_SPLIT(build)
> ])# AC_CANONICAL_BUILD
>
>
> # AC_CANONICAL_HOST
> # -----------------
> AC_DEFUN_ONCE([AC_CANONICAL_HOST],
> [AC_REQUIRE([AC_CANONICAL_BUILD])dnl
> AC_DIVERT([HELP_CANON],
> [[ --host=HOST cross-compile to build programs running on HOST [BUILD]]])dnl
> AC_CACHE_CHECK([host system type], [ac_cv_host],
> [ac_cv_host_alias=$host_alias
> test -z "$ac_cv_host_alias" &&
> ac_cv_host_alias=$ac_cv_build_alias
> ac_cv_host=`$ac_config_sub $ac_cv_host_alias` || exit 1
> ])
> _AC_CANONICAL_SPLIT([host])
> ])# AC_CANONICAL_HOST
>
>
> # AC_CANONICAL_TARGET
> # -------------------
> AC_DEFUN_ONCE([AC_CANONICAL_TARGET],
> [AC_REQUIRE([AC_CANONICAL_HOST])dnl
> AC_BEFORE([$0], [AC_ARG_PROGRAM])dnl
> AC_DIVERT([HELP_CANON],
> [[ --target=TARGET configure for building compilers for TARGET [HOST]]])dnl
> AC_CACHE_CHECK([target system type], [ac_cv_target],
> [dnl Set target_alias.
> ac_cv_target_alias=$target_alias
> test "x$ac_cv_target_alias" = "x" &&
> ac_cv_target_alias=$ac_cv_host_alias
> ac_cv_target=`$ac_config_sub $ac_cv_target_alias` || exit 1
> ])
> _AC_CANONICAL_SPLIT([target])
>
> # The aliases save the names the user supplied, while $host etc.
> # will get canonicalized.
> test -n "$target_alias" &&
> test "$program_prefix$program_suffix$program_transform_name" = \
> NONENONEs,x,x, &&
> program_prefix=${target_alias}-[]dnl
> ])# AC_CANONICAL_TARGET
Akim
