> On Feb 20, 2019, at 4:29 PM, Kees-Jochem Wehrmeijer <henc...@gmail.com> wrote:
>
> With your define/ideal-world form, is there a way to test whether something
> was created using that form? E.g. by generating a predicate like ideal-world?
> That way I can make sure with a contract that my function gets passed an
> ideal-world generator.
Yes, you could define an impersonator property and then wrap your generator
with `impersonate-procedure`:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
#lang racket
(require (except-in racket/generator yield)
(prefix-in gen: (only-in racket/generator yield))
racket/stxparam)
(define-syntax-parameter yield (make-rename-transformer #'gen:yield))
(define-syntax (yield* stx)
(syntax-case stx ()
[(_ . vals)
#'(call-with-values (thunk (gen:yield . vals))
(case-lambda
[() (void)]
[(v) (if (exn? v)
(raise v)
v)]
[vs vs]))]))
(define-values (ideal-world-gen-prop ideal-world-gen? _)
(make-impersonator-property 'ideal-world-gen))
(define-syntax (define/ideal-world stx)
(syntax-case stx ()
[(_ ID . BODY)
#'(define ID
(impersonate-procedure
(syntax-parameterize ([yield (make-rename-transformer #'yield*)])
. BODY)
#f ideal-world-gen-prop #t))]))
(define/ideal-world mygenerator
(generator ()
(with-handlers ([exn? (lambda (e) (yield 42))])
(yield 1)
(yield 2)
(yield 3))))
(mygenerator) ; 1
(mygenerator (exn:fail "Welp" (current-continuation-marks))) ; 42
(generator? mygenerator) ; #t
(ideal-world-gen? mygenerator) ; #t
--
You received this message because you are subscribed to the Google Groups
"Racket Users" group.
To unsubscribe from this group and stop receiving emails from it, send an email
to racket-users+unsubscr...@googlegroups.com.
For more options, visit https://groups.google.com/d/optout.
