[DebianGIS-dev] Bug#336498: grass: broken macro LOC_CHECK_VERSION (also FTBFS on GNU/FreeBSD)

[Markus Neteler]

Hi,

there was a posting in the GRASS developers list

Glynn Clements  glynn at gclements.plus.com
Sat, 5 Nov 2005 17:35:53 +0000

I've committed the following changes:

1. In aclocal.m4, replace LOC_CHECK_VERSION with:

AC_DEFUN(LOC_CHECK_VERSION_STRING,[
AC_MSG_CHECKING($3 version)
ac_save_cppflags="$CPPFLAGS"
CPPFLAGS="$5 $CPPFLAGS"
AC_TRY_RUN([
#include <stdio.h> 
#include <$1>
int main(void) {
 FILE *fp = fopen("conftestdata","w");
 fputs($2, fp);
 return 0;
}
],
[   $4=`cat conftestdata`
    AC_MSG_RESULT($$4)],
[   AC_MSG_ERROR([*** Could not determine $3 version.]) ],
[   $4=$6
    AC_MSG_RESULT([unknown (cross-compiling)]) ])
CPPFLAGS=$ac_save_cppflags
])

AC_DEFUN(LOC_CHECK_VERSION_INT,[
AC_MSG_CHECKING($3 version)
ac_save_cppflags="$CPPFLAGS"
CPPFLAGS="$5 $CPPFLAGS"
AC_TRY_RUN([
#include <stdio.h>
#include <$1>
int main(void) {
 FILE *fp = fopen("conftestdata","w");
 fprintf(fp, "%d", $2);
 return 0;
}
    ],
    [   $4=`cat conftestdata`
        AC_MSG_RESULT($$4)],
    [   AC_MSG_ERROR([*** Could not determine $3 version.]) ],
    [   $4=$6
        AC_MSG_RESULT([unknown (cross-compiling)]) ])
CPPFLAGS=$ac_save_cppflags
])

2. In configure.in:

a) replace:

        LOC_CHECK_VERSION(proj_api.h,PJ_VERSION,External 
PROJ.4,proj_ver,$PROJINC,UNKNOWN)
with:
        LOC_CHECK_VERSION_INT(proj_api.h,PJ_VERSION,External 
PROJ.4,proj_ver,$PROJINC,0)

b) replace:

        LOC_CHECK_VERSION(tcl.h,TCL_VERSION,Tcl,tcl_ver,$TCLINCDIR,UNKNOWN)
with:
        
LOC_CHECK_VERSION_STRING(tcl.h,TCL_VERSION,Tcl,tcl_ver,$TCLINCDIR,UNKNOWN)

c) replace:

        LOC_CHECK_VERSION(tk.h,TK_VERSION,Tk,tk_ver,$TCLINCDIR 
$X_CFLAGS,UNKNOWN)
with:
        LOC_CHECK_VERSION_STRING(tk.h,TK_VERSION,Tk,tk_ver,$TCLINCDIR 
$X_CFLAGS,UNKNOWN)

-- 
Glynn Clements

Reference:
 http://grass.itc.it/pipermail/grass5/2005-November/020069.html



_______________________________________________
Pkg-grass-devel mailing list
Pkg-grass-devel@lists.alioth.debian.org
http://lists.alioth.debian.org/mailman/listinfo/pkg-grass-devel