On Sun, Apr 30, 2006 at 08:32:28AM -0500, Bo Peng wrote:
> > The qt3 included in cygwin is X11 only and is currently broken:
>
> I would like to try, since it may have been fixed (or will be fixed
> soon). The build on cygwin will be really simple if it works.
>
> The problem I have now is that ./configure can *not* find the packages. I used
>
> --with-qt-includes=/usr/include/qt3 --with-qt-libraries=/usr/lib/qt3
>
> ./configure found moc etc easily but still report no qt is found. I
> think it insists on a qt/include, qt/lib directory structure. Do you
> know how to get around of this?
Please, copy i386pe.x-no-rdata to /usr/lib/qt3/mkspecs/cygwin-g++/
and then use the attached lyxconfig-qt3-x11 script to configure lyx:
./lyxconfig-qt3-x11 lyx-1.5.0svn
cd lyx-1.5.0svn/build-x11
make
Does it works?
--
Enrico
/* specific linker script avoiding .rdata sections, for normal executables
for a reference see
http://www.cygwin.com/ml/cygwin/2004-09/msg01101.html
http://www.cygwin.com/ml/cygwin-apps/2004-09/msg00309.html
*/
OUTPUT_FORMAT(pei-i386)
SEARCH_DIR("/usr/i686-pc-cygwin/lib"); SEARCH_DIR("/usr/lib");
SEARCH_DIR("/usr/lib/w32api");
ENTRY(_mainCRTStartup)
SECTIONS
{
.text __image_base__ + __section_alignment__ :
{
*(.init)
*(.text)
*(SORT(.text$*))
*(.glue_7t)
*(.glue_7)
___CTOR_LIST__ = .; __CTOR_LIST__ = . ;
LONG (-1);*(.ctors); *(.ctor); *(SORT(.ctors.*)); LONG
(0);
___DTOR_LIST__ = .; __DTOR_LIST__ = . ;
LONG (-1); *(.dtors); *(.dtor); *(SORT(.dtors.*));
LONG (0);
*(.fini)
/* ??? Why is .gcc_exc here? */
*(.gcc_exc)
PROVIDE (etext = .);
*(.gcc_except_table)
}
/* The Cygwin32 library uses a section to avoid copying certain data
on fork. This used to be named ".data". The linker used
to include this between __data_start__ and __data_end__, but that
breaks building the cygwin32 dll. Instead, we name the section
".data_cygwin_nocopy" and explictly include it after __data_end__. */
.data BLOCK(__section_alignment__) :
{
__data_start__ = . ;
*(.data)
*(.data2)
*(SORT(.data$*))
*(.rdata)
*(SORT(.rdata$*))
*(.eh_frame)
___RUNTIME_PSEUDO_RELOC_LIST__ = .;
__RUNTIME_PSEUDO_RELOC_LIST__ = .;
*(.rdata_runtime_pseudo_reloc)
___RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
__RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
__data_end__ = . ;
*(.data_cygwin_nocopy)
}
.rdata BLOCK(__section_alignment__) :
{
}
.pdata BLOCK(__section_alignment__) :
{
*(.pdata)
}
.bss BLOCK(__section_alignment__) :
{
__bss_start__ = . ;
*(.bss)
*(COMMON)
__bss_end__ = . ;
}
.edata BLOCK(__section_alignment__) :
{
*(.edata)
}
/DISCARD/ :
{
*(.debug$S)
*(.debug$T)
*(.debug$F)
*(.drectve)
}
.idata BLOCK(__section_alignment__) :
{
/* This cannot currently be handled with grouped sections.
See pe.em:sort_sections. */
SORT(*)(.idata$2)
SORT(*)(.idata$3)
/* These zeroes mark the end of the import list. */
LONG (0); LONG (0); LONG (0); LONG (0); LONG (0);
SORT(*)(.idata$4)
SORT(*)(.idata$5)
SORT(*)(.idata$6)
SORT(*)(.idata$7)
}
.CRT BLOCK(__section_alignment__) :
{
___crt_xc_start__ = . ;
*(SORT(.CRT$XC*)) /* C initialization */
___crt_xc_end__ = . ;
___crt_xi_start__ = . ;
*(SORT(.CRT$XI*)) /* C++ initialization */
___crt_xi_end__ = . ;
___crt_xl_start__ = . ;
*(SORT(.CRT$XL*)) /* TLS callbacks */
/* ___crt_xl_end__ is defined in the TLS Directory support code */
___crt_xp_start__ = . ;
*(SORT(.CRT$XP*)) /* Pre-termination */
___crt_xp_end__ = . ;
___crt_xt_start__ = . ;
*(SORT(.CRT$XT*)) /* Termination */
___crt_xt_end__ = . ;
}
.tls BLOCK(__section_alignment__) :
{
___tls_start__ = . ;
*(.tls)
*(.tls$)
*(SORT(.tls$*))
___tls_end__ = . ;
}
.endjunk BLOCK(__section_alignment__) :
{
/* end is deprecated, don't use it */
PROVIDE (end = .);
PROVIDE ( _end = .);
__end__ = .;
}
.rsrc BLOCK(__section_alignment__) :
{
*(.rsrc)
*(SORT(.rsrc$*))
}
.reloc BLOCK(__section_alignment__) :
{
*(.reloc)
}
.stab BLOCK(__section_alignment__) (NOLOAD) :
{
*(.stab)
}
.stabstr BLOCK(__section_alignment__) (NOLOAD) :
{
*(.stabstr)
}
/* DWARF debug sections.
Symbols in the DWARF debugging sections are relative to the beginning
of the section. Unlike other targets that fake this by putting the
section VMA at 0, the PE format will not allow it. */
/* DWARF 1.1 and DWARF 2. */
.debug_aranges BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_aranges)
}
.debug_pubnames BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_pubnames)
}
/* DWARF 2. */
.debug_info BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_info) *(.gnu.linkonce.wi.*)
}
.debug_abbrev BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_abbrev)
}
.debug_line BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_line)
}
.debug_frame BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_frame)
}
.debug_str BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_str)
}
.debug_loc BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_loc)
}
.debug_macinfo BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_macinfo)
}
/* SGI/MIPS DWARF 2 extensions. */
.debug_weaknames BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_weaknames)
}
.debug_funcnames BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_funcnames)
}
.debug_typenames BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_typenames)
}
.debug_varnames BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_varnames)
}
/* DWARF 3. */
.debug_ranges BLOCK(__section_alignment__) (NOLOAD) :
{
*(.debug_ranges)
}
}
#! /bin/sh
# Configuration of the LyX sources suitable for compilation
# of a X11 build using the cygwin compiler.
# author Angus Leeming, modified by Enrico Forestieri
Error () {
test $# -gt 0 && {
echo $* >&2
echo >&2
}
echo "Expecting \"`basename $0` dir [buildtype]\"" >&2
echo "where dir is 'devel','13x', etc. and buildtype is 'debug' or
'release'" >&2
exit 1
}
test \( $# -eq 1 \) -o \( $# -eq 2 \) || Error
test -d "$1" || Error "Directory '$1' does not exist."
SRCDIR=$1
test -s "${SRCDIR}/configure" || \
Error "'${SRCDIR}/configure' does not exist. Run './autogen.sh' in
'${SRCDIR}'."
test $# -eq 2 && BUILDTYPE=$2 || BUILDTYPE=release
test \( "$BUILDTYPE" = "debug" \) -o \( "$BUILDTYPE" = "release" \) || \
Error "Unrecognized debugopt: $BUILDTYPE"
echo "Configuring ${SRCDIR} for a ${BUILDTYPE} build"
FRONTEND=qt
QTDIR=/usr/lib/qt3
FRONTEND_FLAGS="--with-qt-dir='${QTDIR}' --with-qt-includes=/usr/include/qt3"
QT_LD_SCRIPT=/usr/lib/qt3/mkspecs/cygwin-g++/i386pe.x-no-rdata
BUILDDIR=${SRCDIR}/build-x11
test "${BUILDDIR}" != "${SRCDIR}" -a ! -d "${BUILDDIR}" && {
mkdir "${BUILDDIR}" || Error "Unable to create build dir, ${BUILDDIR}."
}
test "$BUILDTYPE" = "release" && {
LDFLAGS="-Wl,--enable-runtime-pseudo-reloc -Wl,--script,$QT_LD_SCRIPT -Wl,-s"
OPTFLAG="-O2"
} || {
LDFLAGS="-Wl,--enable-runtime-pseudo-reloc -Wl,--script,$QT_LD_SCRIPT"
OPTFLAG="-g"
}
CONFIGURE="../configure-x11"
QT_EXTRALIBS="-L\/usr\/X11R6\/lib -lGL -lXmu -lXi -lXrender -lXrandr -lXcursor
-lXft -lfreetype -lfontconfig -lXext -lX11 -lSM -lICE -lresolv -lz -lpthread"
sed "
# Let's speed up recognition of the Qt library
/for libname in -lqt-mt/s/\(-lqt-mt\)\(.*\)\(-lqt\);/\3\2\1;/
# Omit -Wl,--export-all-symbols in LDFLAGS
/LDFLAGS=\"\$LDFLAGS \$WIN32_LD_EXPORT_ALL_SYMBOLS\"/s/LDFLAGS/true\t\#LDFLAGS/
# Add required libraries to the tests for the Qt library
/LIBS=\"\$LIBS \$libname\"/s/libname/libname $QT_EXTRALIBS/
/LIBS=\"\$LIBS \$QT_LIB\"/s/QT_LIB/QT_LIB $QT_EXTRALIBS/" \
${SRCDIR}/configure > ${SRCDIR}/configure-x11
chmod u+x ${SRCDIR}/configure-x11
# Set up configure itself
#========================
CONFIGURE="${CONFIGURE} --disable-maintainer-mode --disable-assertions \
--disable-debug --disable-stdlib-debug --enable-optimization='${OPTFLAG}' \
--disable-pch --disable-concept-checks \
--with-included-gettext --with-aspell \
--with-frontend='${FRONTEND}' ${FRONTEND_FLAGS} \
--with-extra-lib=/usr/local/lib \
--prefix=/usr/local \
LDFLAGS='${LDFLAGS}'"
echo "Build directory is ${BUILDDIR}"
echo "${CONFIGURE}"
cd "${BUILDDIR}"
eval "${CONFIGURE}"
# The end
