configure.ac | 6 ++
m4/introspection.m4 | 94 +++++++++++++++++++++++++++++++++++++
sysui/desktop/share/create_tree.sh | 13 +++++
3 files changed, 113 insertions(+)
New commits:
commit 8f2aace934eb2a91a273b6104de6383108b5c82a
Author: Pranav Kant <pran...@gnome.org>
Date: Sat Aug 15 18:48:53 2015 +0530
create_tree.sh: Generate g-i files
Change-Id: I1749b5b02018cfe6f85a13aed8de4b31a09788e3
Reviewed-on: https://gerrit.libreoffice.org/18494
Reviewed-by: Miklos Vajna <vmik...@collabora.co.uk>
Tested-by: Miklos Vajna <vmik...@collabora.co.uk>
diff --git a/configure.ac b/configure.ac
index 65a313a..dda7e15 100644
--- a/configure.ac
+++ b/configure.ac
@@ -201,6 +201,11 @@ SRC_ROOT=`pwd`
cd $BUILDDIR
x_Cygwin=[\#]
+dnl ======================================
+dnl Required GObject introspection version
+dnl ======================================
+INTROSPECTION_REQUIRED_VERSION=1.32.0
+
dnl ===================================================================
dnl Search all the common names for GNU Make
dnl ===================================================================
@@ -9957,6 +9962,7 @@ if test "x$enable_gtk3" = "xyes"; then
PKG_CHECK_MODULES(GTK3, gtk+-3.0 >= 3.8 gtk+-unix-print-3.0
gmodule-no-export-2.0 glib-2.0 >= 2.38 cairo, ENABLE_GTK3="TRUE",
ENABLE_GTK3="")
if test "x$ENABLE_GTK3" = "xTRUE"; then
R="gtk3"
+ GOBJECT_INTROSPECTION_CHECK(INTROSPECTION_REQUIRED_VERSION)
else
AC_MSG_ERROR([gtk3 or dependent libraries of the correct versions, not
found])
fi
diff --git a/m4/introspection.m4 b/m4/introspection.m4
new file mode 100644
index 0000000..532bad8
--- /dev/null
+++ b/m4/introspection.m4
@@ -0,0 +1,94 @@
+dnl -*- mode: autoconf -*-
+dnl Copyright 2009 Johan Dahlin
+dnl
+dnl This file is free software; the author(s) gives unlimited
+dnl permission to copy and/or distribute it, with or without
+dnl modifications, as long as this notice is preserved.
+dnl
+
+# serial 1
+
+m4_define([_GOBJECT_INTROSPECTION_CHECK_INTERNAL],
+[
+ AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
+ AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
+ AC_BEFORE([LT_INIT],[$0])dnl setup libtool first
+
+ dnl enable/disable introspection
+ m4_if([$2], [require],
+ [dnl
+ enable_introspection=yes
+ ],[dnl
+ AC_ARG_ENABLE(introspection,
+
AS_HELP_STRING([--enable-introspection[=@<:@no/auto/yes@:>@]],
+ [Enable introspection for this build]),,
+ [enable_introspection=auto])
+ ])dnl
+
+ AC_MSG_CHECKING([for gobject-introspection])
+
+ dnl presence/version checking
+ AS_CASE([$enable_introspection],
+ [no], [dnl
+ found_introspection="no (disabled, use --enable-introspection to
enable)"
+ ],dnl
+ [yes],[dnl
+ PKG_CHECK_EXISTS([gobject-introspection-1.0],,
+ AC_MSG_ERROR([gobject-introspection-1.0 is not
installed]))
+ PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1],
+ found_introspection=yes,
+ AC_MSG_ERROR([You need to have gobject-introspection
>= $1 installed to build AC_PACKAGE_NAME]))
+ ],dnl
+ [auto],[dnl
+ PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $1],
found_introspection=yes, found_introspection=no)
+ dnl Canonicalize enable_introspection
+ enable_introspection=$found_introspection
+ ],dnl
+ [dnl
+ AC_MSG_ERROR([invalid argument passed to --enable-introspection,
should be one of @<:@no/auto/yes@:>@])
+ ])dnl
+
+ AC_MSG_RESULT([$found_introspection])
+
+ INTROSPECTION_SCANNER=
+ INTROSPECTION_COMPILER=
+ INTROSPECTION_GENERATE=
+ INTROSPECTION_GIRDIR=
+ INTROSPECTION_TYPELIBDIR=
+ if test "x$found_introspection" = "xyes"; then
+ INTROSPECTION_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner
gobject-introspection-1.0`
+ INTROSPECTION_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler
gobject-introspection-1.0`
+ INTROSPECTION_GENERATE=`$PKG_CONFIG --variable=g_ir_generate
gobject-introspection-1.0`
+ INTROSPECTION_GIRDIR=`$PKG_CONFIG --variable=girdir
gobject-introspection-1.0`
+ INTROSPECTION_TYPELIBDIR="$($PKG_CONFIG --variable=typelibdir
gobject-introspection-1.0)"
+ INTROSPECTION_CFLAGS=`$PKG_CONFIG --cflags gobject-introspection-1.0`
+ INTROSPECTION_LIBS=`$PKG_CONFIG --libs gobject-introspection-1.0`
+ INTROSPECTION_MAKEFILE=`$PKG_CONFIG --variable=datadir
gobject-introspection-1.0`/gobject-introspection-1.0/Makefile.introspection
+ fi
+ AC_SUBST(INTROSPECTION_SCANNER)
+ AC_SUBST(INTROSPECTION_COMPILER)
+ AC_SUBST(INTROSPECTION_GENERATE)
+ AC_SUBST(INTROSPECTION_GIRDIR)
+ AC_SUBST(INTROSPECTION_TYPELIBDIR)
+ AC_SUBST(INTROSPECTION_CFLAGS)
+ AC_SUBST(INTROSPECTION_LIBS)
+ AC_SUBST(INTROSPECTION_MAKEFILE)
+])
+
+
+dnl Usage:
+dnl GOBJECT_INTROSPECTION_CHECK([minimum-g-i-version])
+
+AC_DEFUN([GOBJECT_INTROSPECTION_CHECK],
+[
+ _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1])
+])
+
+dnl Usage:
+dnl GOBJECT_INTROSPECTION_REQUIRE([minimum-g-i-version])
+
+
+AC_DEFUN([GOBJECT_INTROSPECTION_REQUIRE],
+[
+ _GOBJECT_INTROSPECTION_CHECK_INTERNAL([$1], [require])
+])
diff --git a/sysui/desktop/share/create_tree.sh
b/sysui/desktop/share/create_tree.sh
index c6be0bb..45b7c6c 100755
--- a/sysui/desktop/share/create_tree.sh
+++ b/sysui/desktop/share/create_tree.sh
@@ -87,3 +87,16 @@ for i in base calc draw impress writer; do
cp "${APPDATA_SOURCE_DIR}/libreoffice-${i}.appdata.xml"
"${DESTDIR}/${PREFIXDIR}/share/appdata/${PREFIX}-${i}.appdata.xml"
done
+# Generate gobject-introspection files
+mkdir -p "${DESTDIR}/${PREFIXDIR}/share/gir-1.0"
+g-ir-scanner "${SRCDIR}/include/LibreOfficeKit/LibreOfficeKitGtk.h"
"${SRCDIR}/libreofficekit/source/gtk/lokdocview.cxx" \
+ `${PKG_CONFIG} --cflags gobject-introspection-1.0 gtk+-3.0`
-I"${SRCDIR}/include/" \
+ --include=GLib-2.0 --include=GObject-2.0 --include=Gio-2.0 \
+ --library=libreofficekitgtk
--library-path="${DESTDIR}/${INSTALLDIR}/program" \
+ --include=Gdk-3.0 --include=GdkPixbuf-2.0 --include=Gtk-3.0 \
+ --namespace=LOKDocView --nsversion=0.1 --identifier-prefix=LOKDoc
--symbol-prefix=lok_doc \
+
--output="${DESTDIR}/${PREFIXDIR}/share/gir-1.0/LOKDocView-0.1.gir" --warn-all
--no-libtool
+
+mkdir -p "${DESTDIR}/${LIBDIR}/girepository-1.0"
+g-ir-compiler "${DESTDIR}/${PREFIXDIR}/share/gir-1.0/LOKDocView-0.1.gir" \
+
--output="${DESTDIR}/${LIBDIR}/girepository-1.0/LOKDocView-0.1.typelib"
_______________________________________________
Libreoffice-commits mailing list
libreoffice-comm...@lists.freedesktop.org
http://lists.freedesktop.org/mailman/listinfo/libreoffice-commits
