On Wed, 03 Feb 2010, smu johnson wrote:
Hi,
> As far as the timestamp stuff... have found that using FSETDATETIME and
> trying to set only one of the options, either DATE, or TIME, results in the
> other one getting timestamped to a NOW() type time. Hence I wrote my cludge
> in Clipper get around that... I tried all sorts of tricks..
> HB_FSETDATETIME(file, nil, time), (file, , time)... etc.. and nothing
> seemed to work.
If you do not pass date and/or time then current date and/or current time
is used,
HB_FSETDATETIME( cFilename, dDate )
works like:
HB_FSETDATETIME( cFilename, dDate, time() )
and
HB_FSETDATETIME( cFilename,, cTime )
works like:
HB_FSETDATETIME( cFilename, date(), cTime )
If you want to change only time or only data then you have to read
current values from the file, i.e.:
FUNCTION MY_FSETDATE( cFilename, dDate )
LOCAL date, time
IF HB_FGETDATETIME( cFilename, @date, @time )
RETURN HB_FSETDATETIME( cFilename, dDate, time )
ENDIF
RETURN .F.
FUNCTION MY_FSETTIME( cFilename, cTime )
LOCAL date, time
IF HB_FGETDATETIME( cFilename, @date, @time )
RETURN HB_FSETDATETIME( cFilename, date, cTime )
ENDIF
RETURN .F.
Please also remember that in modern file systems more then one timestamp
value is bound with file. You may have creation time, access time,
modify time, etc...
Not all of them can be changed by normal user.
Which will be updated depends on used OS and FS.
best regards,
Przemek
_______________________________________________
Harbour mailing list (attachment size limit: 40KB)
Harbour@harbour-project.org
http://lists.harbour-project.org/mailman/listinfo/harbour
