On Tue, 16 Jun 2009, Szak�ts Viktor wrote:
> Thanks Davor.
> Here's a slightly tweaked version:
> ---
> #include "common.ch"
> #include "fileio.ch"
>
> FUNCTION hb_processRun( cCommand, cStdIn, cStdOut, cStdErr )
> LOCAL hProcess
> LOCAL hStdIn, hStdOut, hStdErr
> LOCAL nErrorLevel
> hProcess := hb_processOpen( cCommand, @hStdIn, @hStdOut, @hStdErr )
> IF hProcess == F_ERROR
> nErrorLevel := F_ERROR
> ELSE
> IF ISCHARACTER( cStdIn ) .AND. Len( cStdIn ) > 0
> FWrite( hStdIn, cStdIn )
> ENDIF
> IF PCount() >= 3
> cStdOut := ReadHnd( hStdOut )
> ENDIF
> IF PCount() >= 4
> cStdErr := ReadHnd( hStdErr )
> ENDIF
> nErrorLevel := hb_processValue( hProcess )
> hb_processClose( hProcess, .T. )
> FClose( hStdIn )
> FClose( hStdOut )
> FClose( hStdErr )
> ENDIF
> RETURN nErrorLevel
>
> STATIC FUNCTION ReadHnd( hHandle )
> LOCAL cBuffer := Space( 4096 )
> LOCAL cOutput := ""
> LOCAL nLen
> DO WHILE ( nLen := FRead( hHandle, @cBuffer, Len( cBuffer ) ) ) > 0
> cOutPut += SubStr( cBuffer, 1, nLen )
> ENDDO
> RETURN cOutput
> ---
> Any opinions on including it in core RTL? Przemek?
Nice but it will not work as expected in all cases.
If stderr output is longer then PIPE buffer size this code will create
deadlock. If if passed stdin is longer then PIPE buffer size then is
truncated in hidden.
This deadlock in this code can be used to exploit in the following way:
PROC MAIN( x )
LOCAL nResult, cCommand, cStdIn, cStdOut, cStdErr
IF PCount() == 0
cCommand := hb_progName() + " test"
nResult := hb_processRun( cCommand, cStdIn, @cStdOut, @cStdErr )
? cCommand, "=>", nResult
? "stdout size:", len( cStdOut )
? "stderr size:", len( cStdErr )
ELSE
OutStd( repl( ".stdout.", 1 ) )
OutErr( repl( ".stderr.", 100000 ) ) // huge stderr outout,
// longer then PIPE buffer size
ENDIF
RETURN
It means that in such version this function cannot be used in SVN.
In general we do not have .prg wrappers to implement such functionality
only in .prg level. In *nixes it has to be implement using select()
or similar poll function. In Windows it's necessary to use
WaitForMultipleObjects(). I do not know OS2 API so I cannot answer how
(and if) it can be implemented in this OS. Probably yes. DOS does not
support simultaneous process execution so it does not have any hb_process*()
functions though function like above hb_processRun() can be implemented
using temporary files.
If you think that such function will be usable then I can implement it
in some spare time but it will have to be done in C due to low level
platform differences. As alternative we can create hb_processCanRead()
function for *nixes and MS-Windows as wrapper to select() and
WaitForMultipleObjects() and use this function in above hb_processRun()
code to eliminate deadlock.
best regards,
Przemek
_______________________________________________
Harbour mailing list
Harbour@harbour-project.org
http://lists.harbour-project.org/mailman/listinfo/harbour
