commit: a2b3f70fe646cb50d904ef91915ddfed1da0296c
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 20 02:18:39 2024 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Nov 20 02:18:39 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a2b3f70f
dev-libs/libinput: Version bump to 1.27.0
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-libs/libinput/Manifest | 1 +
dev-libs/libinput/libinput-1.27.0.ebuild | 102 +++++++++++++++++++++++++++++++
2 files changed, 103 insertions(+)
diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 9817dfa9a10b..055483dfd1a9 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
DIST libinput-1.26.2.tar.bz2 824312 BLAKE2B
df463f377cf2f246f6b5b35bdc69039830b4eb5b836a8df9698330140b1bc4b31c7dd50d8ffdec7c935e8b14909d98436ce8f1f9a6d0120e4b72f29381f9b697
SHA512
51fab62e1bfb6007287e1219bf458a351806ce685e6e7ba5360062c863f0811da75acc6ec92aef7f9e0556dac0413fbe43a4744885f7449e38036130112907a6
+DIST libinput-1.27.0.tar.bz2 843722 BLAKE2B
342166bc48943a65e70be274a4b946769b27029b8d3014b081f268537c7bbdf5c7e9be5e2c2b547e1433e444c9e5b2994a4d03f7894afe15b923ba09cd58d490
SHA512
ddfb4a16cbd40f8e55a536f8e18e77bb26113690bd4188d2e6ea04c1a906d8392d4df340d4e24f20c5152b3ef7d727702229a86fc27ad50c5ea9a85a58d3e24a
diff --git a/dev-libs/libinput/libinput-1.27.0.ebuild
b/dev-libs/libinput/libinput-1.27.0.ebuild
new file mode 100644
index 000000000000..2dcde3640a39
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.27.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 2014-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit meson optfeature python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/
https://gitlab.freedesktop.org/libinput/libinput";
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2";
+
+LICENSE="MIT"
+SLOT="0/10"
+if [[ $(ver_cut 3) -lt 900 ]] ; then
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc
~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ input_devices_wacom? ( >=dev-libs/libwacom-0.27:= )
+ >=dev-libs/libevdev-1.9.902
+ >=sys-libs/mtdev-1.1
+ virtual/libudev:=
+ virtual/udev
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( >=dev-libs/check-0.9.10 )
+"
+BDEPEND="
+ virtual/pkgconfig
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/commonmark[${PYTHON_USEDEP}]
+ dev-python/recommonmark[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]
+ ')
+ >=app-text/doxygen-1.8.3
+ >=media-gfx/graphviz-2.38.0
+ )
+ test? (
+ $(python_gen_any_dep '
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-python/pytest-xdist[${PYTHON_USEDEP}]
+ ')
+ )
+"
+# test? ( dev-debug/valgrind )
+
+python_check_deps() {
+ if use doc; then
+ python_has_version \
+ "dev-python/commonmark[${PYTHON_USEDEP}]" \
+ "dev-python/recommonmark[${PYTHON_USEDEP}]" \
+ "dev-python/sphinx[${PYTHON_USEDEP}]" \
+ ">=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]"
\
+ || return
+ fi
+ if use test; then
+ python_has_version \
+ "dev-python/pytest[${PYTHON_USEDEP}]" \
+ "dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
+ || return
+ fi
+}
+
+src_prepare() {
+ default
+ sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+ # gui can be built but will not be installed
+ local emesonargs=(
+ -Ddebug-gui=false
+ $(meson_use doc documentation)
+ $(meson_use input_devices_wacom libwacom)
+ $(meson_use test tests)
+ -Dudev-dir="${EPREFIX}$(get_udevdir)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc ; then
+ docinto html
+ dodoc -r "${BUILD_DIR}"/Documentation/.
+ fi
+}
+
+pkg_postinst() {
+ optfeature "measure and replay tools" dev-python/libevdev
+ udev_reload
+}
+
+pkg_postrm() {
+ udev_reload
+}
