commit: da40443cd0bc33f3b621ca9866ff0bfd80a7f9cf
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 19 14:34:58 2023 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Oct 19 15:11:02 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da40443c
kde-frameworks/plasma: 5.111.0 version bump
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-frameworks/plasma/Manifest | 1 +
kde-frameworks/plasma/plasma-5.111.0.ebuild | 70 +++++++++++++++++++++++++++++
2 files changed, 71 insertions(+)
diff --git a/kde-frameworks/plasma/Manifest b/kde-frameworks/plasma/Manifest
index a3b2f550dee0..d1afc0677b64 100644
--- a/kde-frameworks/plasma/Manifest
+++ b/kde-frameworks/plasma/Manifest
@@ -1 +1,2 @@
DIST plasma-framework-5.110.0.tar.xz 3310724 BLAKE2B
c98fb699f40d50ddcba0cabdd9cd13a06125e27b1ff6c2c922624ba45107f98e70ecc3cbc70634414685d5dff2bb2a198bd819e9f59f37ca9fcb3d5d7a991747
SHA512
dda20bee357c18405a56cb8cd0b73d1da3f8838921290e5890873b80d1b970a82f18194c26a598c670e85bb4db16477ef770d5e1d7d19d79b210dec574704039
+DIST plasma-framework-5.111.0.tar.xz 3310696 BLAKE2B
12c04a38e0ae831388f4adb707a53c6842aa7a4ae63ee857e8feeb43b86f71d66370d780a0332767565b3011c79a29f6fe5acafa4df8706d6d2b7503e678414d
SHA512
6e8a4821b295743b552e95900ed3f8a0ffdd4dc81a05748b4c1f59584f34638b1e0ddd8eef3686c71d9f61e5f11c4629982badb6632918e5c2296c60a6338462
diff --git a/kde-frameworks/plasma/plasma-5.111.0.ebuild
b/kde-frameworks/plasma/plasma-5.111.0.ebuild
new file mode 100644
index 000000000000..5c95ea0d7405
--- /dev/null
+++ b/kde-frameworks/plasma/plasma-5.111.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="${PN}-framework"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Plasma library and runtime components based upon KF5 and Qt5"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gles2-only man wayland"
+
+RESTRICT="test"
+
+# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
+RDEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5[gles2-only=,X]
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtsql-${QTMIN}:5
+ >=dev-qt/qtsvg-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ =kde-frameworks/kactivities-${PVCUT}*:5
+ =kde-frameworks/karchive-${PVCUT}*:5
+ =kde-frameworks/kconfig-${PVCUT}*:5[qml]
+ =kde-frameworks/kconfigwidgets-${PVCUT}*:5
+ =kde-frameworks/kcoreaddons-${PVCUT}*:5
+ =kde-frameworks/kdeclarative-${PVCUT}*:5
+ =kde-frameworks/kglobalaccel-${PVCUT}*:5
+ =kde-frameworks/kguiaddons-${PVCUT}*:5
+ =kde-frameworks/ki18n-${PVCUT}*:5
+ =kde-frameworks/kiconthemes-${PVCUT}*:5
+ =kde-frameworks/kio-${PVCUT}*:5
+ =kde-frameworks/kirigami-${PVCUT}*:5
+ =kde-frameworks/knotifications-${PVCUT}*:5
+ =kde-frameworks/kpackage-${PVCUT}*:5
+ =kde-frameworks/kservice-${PVCUT}*:5
+ =kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+ =kde-frameworks/kwindowsystem-${PVCUT}*:5[X]
+ =kde-frameworks/kxmlgui-${PVCUT}*:5
+ x11-libs/libX11
+ x11-libs/libxcb
+ !gles2-only? ( media-libs/libglvnd[X] )
+ wayland? (
+ =kde-frameworks/kwayland-${PVCUT}*:5
+ media-libs/libglvnd
+ )
+"
+DEPEND="${RDEPEND}
+ x11-base/xorg-proto
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_DESKTOPTHEMES=ON # TODO: switch for KF6 compat
+ $(cmake_use_find_package !gles2-only OpenGL)
+ $(cmake_use_find_package man KF5DocTools)
+ $(cmake_use_find_package wayland EGL)
+ $(cmake_use_find_package wayland KF5Wayland)
+ )
+
+ ecm_src_configure
+}
