[gentoo-commits] repo/gentoo:master commit in: dev-python/cattrs/

[Michał Górny]

commit:     ad1f3240b1b0871871e9e5580056b151c1615c94
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 31 06:08:13 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 31 06:33:40 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad1f3240

dev-python/cattrs: Bump to 23.1.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cattrs/Manifest             |  1 +
 dev-python/cattrs/cattrs-23.1.1.ebuild | 56 ++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-python/cattrs/Manifest b/dev-python/cattrs/Manifest
index c7462bd373d9..09f886ebb590 100644
--- a/dev-python/cattrs/Manifest
+++ b/dev-python/cattrs/Manifest
@@ -1 +1,2 @@
 DIST cattrs-22.2.0.gh.tar.gz 117001 BLAKE2B 
34601cf48c582da2d9aa8d741a08919b5f06043bc6ba6b072d8b0934e90e781349b1325ced478ca0b42b50db1f7fe2a6d3cd16ac29609efd72c9aa894debfe9e
 SHA512 
d198864402f56d4e9403c61ee3d9d109c5eac3350908afa1e244dbe31e4bc986271fcb4c72bde9cdaa9ee865c6a8b81de68ec0d51490ed658b410714e1fc550c
+DIST cattrs-23.1.1.gh.tar.gz 602294 BLAKE2B 
c0be7dc8979919c4d29f9bd51203d219b9d65bbaa271a38f4d1d6c705121a5c9747c3b8a29431de8ea6769baeae67323b8bd6f133f9fd6c80aa1f3bbf969b4d2
 SHA512 
8a048ce214ed1aa4b138164e3cd7e39fec84ee3d46f167dda402e3de0041fb0548b2e75051c63694a5baf59c78705823247e4204408f5d0b410a9aabdc68c7e3

diff --git a/dev-python/cattrs/cattrs-23.1.1.ebuild 
b/dev-python/cattrs/cattrs-23.1.1.ebuild
new file mode 100644
index 000000000000..9c62d3accf1e
--- /dev/null
+++ b/dev-python/cattrs/cattrs-23.1.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Composable complex class support for attrs and dataclasses"
+HOMEPAGE="
+       https://pypi.org/project/cattrs/
+       https://github.com/python-attrs/cattrs/
+"
+SRC_URI="
+       https://github.com/python-attrs/cattrs/archive/v${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+       >=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep '
+               dev-python/exceptiongroup[${PYTHON_USEDEP}]
+       ' 3.{9..10})
+"
+BDEPEND="
+       test? (
+               >=dev-python/cbor2-5.4.6[${PYTHON_USEDEP}]
+               >=dev-python/hypothesis-6.54.5[${PYTHON_USEDEP}]
+               >=dev-python/immutables-0.18[${PYTHON_USEDEP}]
+               >=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+               >=dev-python/orjson-3.5.2[${PYTHON_USEDEP}]
+               >=dev-python/pymongo-4.2.0[${PYTHON_USEDEP}]
+               >=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
+               >=dev-python/tomlkit-0.11.4[${PYTHON_USEDEP}]
+               >=dev-python/ujson-5.4.0[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       sed -e 's:--benchmark.*::' \
+               -e '/addopts/d' \
+               -i pyproject.toml || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       epytest tests
+}