[gentoo-commits] repo/gentoo:master commit in: dev-libs/qcoro5/

[Andreas Sturmlechner]

commit:     7f13644f22733d290f54b2f189c1f60664865a4f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 26 11:02:48 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Mar 26 11:03:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7f13644f

dev-libs/qcoro5: add 0.8.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/qcoro5/Manifest            |  1 +
 dev-libs/qcoro5/qcoro5-0.8.0.ebuild | 64 +++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-libs/qcoro5/Manifest b/dev-libs/qcoro5/Manifest
index b7f0cb239fa9..b794ca870de0 100644
--- a/dev-libs/qcoro5/Manifest
+++ b/dev-libs/qcoro5/Manifest
@@ -1 +1,2 @@
 DIST qcoro5-0.7.0.tar.gz 135419 BLAKE2B 
8f593e76e960349090cea649848c6b3d422125f1bd292ec79026d0cdab7f7e7de77ec409d442c624efe2683a24dd7715ba108f400e154813b6b3da3eb0b8fc09
 SHA512 
cd49f957d30b63ee70080425c1ed8ffe05c09f7d5e3c6f043c2a9e66eee9a537c9bd6f12ea54fa9fa53871c5d6e5c4502e2c4a10c30eb3bf017505ba875838ba
+DIST qcoro5-0.8.0.tar.gz 139254 BLAKE2B 
979e1744951742c7a3f5a70d291e0e63d6be1d73794c9af32ef48b8e440c1919ae487cf07d1896cc2a8e7bdf8a51cac14f81a6e17689b57a93cfb71db3500282
 SHA512 
bdcf6f9113e5dde57fb56abdeb5106dbba8892ecc6c11d9f4b8b653570ffb0e25f63ee0fe87cd9008e02b99b76f959b9af00b2875420517b13295d6b108db2cc

diff --git a/dev-libs/qcoro5/qcoro5-0.8.0.ebuild 
b/dev-libs/qcoro5/qcoro5-0.8.0.ebuild
new file mode 100644
index 000000000000..b7f45410f814
--- /dev/null
+++ b/dev-libs/qcoro5/qcoro5-0.8.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/danvratil/${PN/5/}";
+else
+       
SRC_URI="https://github.com/danvratil/${PN/5/}/archive/refs/tags/v${PV}.tar.gz 
-> ${P}.tar.gz"
+       S="${WORKDIR}/${P/5/}"
+       KEYWORDS="~amd64 ~arm64 ~ppc64"
+fi
+
+DESCRIPTION="C++ Coroutine Library for Qt5"
+HOMEPAGE="https://qcoro.dvratil.cz/ https://github.com/danvratil/qcoro";
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="dbus examples +network qml test websockets"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       dev-qt/qtcore:5
+       dbus? ( dev-qt/qtdbus:5 )
+       network? ( dev-qt/qtnetwork:5 )
+       qml? ( dev-qt/qtdeclarative:5= )
+       websockets? ( dev-qt/qtwebsockets:5 )
+"
+DEPEND="${RDEPEND}
+       examples? (
+               dev-qt/qtconcurrent:5
+               dev-qt/qtwidgets:5
+       )
+       test? (
+               dev-qt/qtconcurrent:5
+               dev-qt/qttest:5
+       )
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DUSE_QT_VERSION=5
+               -DQCORO_BUILD_EXAMPLES=$(usex examples)
+               -DQCORO_WITH_QTDBUS=$(usex dbus)
+               -DQCORO_WITH_QTNETWORK=$(usex network)
+               -DQCORO_WITH_QML=$(usex qml)
+               -DQCORO_WITH_QTQUICK=$(usex qml)
+               -DBUILD_TESTING=$(usex test)
+               -DQCORO_WITH_QTWEBSOCKETS=$(usex websockets)
+       )
+       cmake_src_configure
+}
+
+src_install() {
+       if use examples; then
+               docinto examples
+               dodoc -r examples/*
+       fi
+       cmake_src_install
+}