[gentoo-commits] repo/gentoo:master commit in: dev-python/pikepdf/

[Michał Górny]

commit:     21b3a376e5253a44012f43fdaed2488eafc76757
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 26 02:48:38 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Mar 26 03:01:58 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=21b3a376

dev-python/pikepdf: Bump to 7.1.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pikepdf/Manifest             |  1 +
 dev-python/pikepdf/pikepdf-7.1.2.ebuild | 58 +++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 41f40b84aa30..5b8f6ccc5e70 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1 +1,2 @@
 DIST pikepdf-7.1.1.tar.gz 2911088 BLAKE2B 
0c65830ce4ec8f36814dd2a523dcc753380df7b6e4ce176b0e61e1e7f5f8bbfa01c9ef1ab093cbfeaf7dd1c67ada4e7dca53cf6da8b04cbceca825276179627b
 SHA512 
e59bf20008df058aa2bbccedf71294ffc39a7aa774eeebcc33214ec7864be461959317bbd92f3df415690bb4ef3bbb63f9c05c613bcb9023b680637c07f3bd75
+DIST pikepdf-7.1.2.tar.gz 2911232 BLAKE2B 
14b6b90617b7bd30f6a595337751f586cbe7d94e46fb4adbc233d542b6b96853b4cd0fb815e956a9865c97f14800065c9793c340f9de814a23f7a4c90903012f
 SHA512 
2e8b75627d296689b044bec1a33740e8a3de5fbb8fdfe3aa64e4ddd2a8c2f3f327c9b553e41364d2bfc5d821ff2a84f79fed917626930a543edf94286b85bcab

diff --git a/dev-python/pikepdf/pikepdf-7.1.2.ebuild 
b/dev-python/pikepdf/pikepdf-7.1.2.ebuild
new file mode 100644
index 000000000000..68c143cdaf70
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-7.1.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+       https://github.com/pikepdf/pikepdf/
+       https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86"
+
+DEPEND="
+       >=app-text/qpdf-11.1.1:0=
+"
+RDEPEND="
+       ${DEPEND}
+       dev-python/deprecation[${PYTHON_USEDEP}]
+       >=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+       dev-python/packaging[${PYTHON_USEDEP}]
+       >=dev-python/pillow-9.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       >=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+       >=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+       test? (
+               >=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+               >=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+               >=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+               >=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+               >=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+               >=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+               >=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+               $(python_gen_cond_dep '
+                       dev-python/tomli[${PYTHON_USEDEP}]
+               ' 3.{8..10})
+       )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+       # fragile to system load
+       tests/test_image_access.py::test_random_image
+)
+
+src_prepare() {
+       sed -e '/-n auto/d' -i pyproject.toml || die
+       distutils-r1_src_prepare
+}