commit: a6901600c1dbb5c5188bed18499e4616ad5f70e1
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 6 13:20:02 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar 6 14:04:54 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a6901600
dev-python/nbclassic: Bump to 0.5.3
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/nbclassic/Manifest | 1 +
dev-python/nbclassic/nbclassic-0.5.3.ebuild | 84 +++++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
diff --git a/dev-python/nbclassic/Manifest b/dev-python/nbclassic/Manifest
index b377c2e19a91..86369cfad9f7 100644
--- a/dev-python/nbclassic/Manifest
+++ b/dev-python/nbclassic/Manifest
@@ -1,2 +1,3 @@
DIST nbclassic-0.5.1.tar.gz 20178622 BLAKE2B
1ff79c9af218011c697016ecef149f42e683607eebb8e199ef75957d9d3127858ce8f443aeedb60844e3277b4c8cd4959d123658a5103ab2112fec469ef01a96
SHA512
1dabc27ad115d1961e7881e7a51653449cae291c74aea222bbf92d49cb7bc9657ae1f1d9a81eafbd70bc0cafd57b75cd2c76bebf91aabc5fdd9eede534f1cec9
DIST nbclassic-0.5.2.tar.gz 20182217 BLAKE2B
02a91ea461acf56c8aeafab5d2af726c21add89bdfd651be9225fb3ec278de76bf8ab76c30d2e16f3a7b7a7d17f13a58907a14b2389c029dd0bb74af565115d0
SHA512
c26b86ee5958a6bb2b891f0bfff7fd90054727977a5cb29aacf1681e56490dcc7b8275709d74597e7d99940493a39499b8c8832a92fcf1a57955f20e100a10a4
+DIST nbclassic-0.5.3.tar.gz 20199979 BLAKE2B
aa509bbd2bab51b94f475e81b7e1c5661370e850680df8f64c86d76ff2aed7a84a0e6c00f36a695ef7f84cdc731fb7613107abc96fb13a3127ded6689d6e81a1
SHA512
07e26d4cb30e3388420ced182a31a050419f4a872256efca6684e4af0e08ec8bf7f6f14f127fe1391457ad5fc792377a1a7bafc0fa1a92eec455454c6321a9ec
diff --git a/dev-python/nbclassic/nbclassic-0.5.3.ebuild
b/dev-python/nbclassic/nbclassic-0.5.3.ebuild
new file mode 100644
index 000000000000..965e97187b26
--- /dev/null
+++ b/dev-python/nbclassic/nbclassic-0.5.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=jupyter
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+ https://jupyter.org/
+ https://github.com/jupyter/nbclassic/
+ https://pypi.org/project/nbclassic/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ dev-python/argon2-cffi[${PYTHON_USEDEP}]
+ dev-python/ipykernel[${PYTHON_USEDEP}]
+ dev-python/ipython_genutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ >=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+ >=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+ >=dev-python/nbconvert-5[${PYTHON_USEDEP}]
+ dev-python/nbformat[${PYTHON_USEDEP}]
+ >=dev-python/nest_asyncio-1.5[${PYTHON_USEDEP}]
+ >=dev-python/notebook_shim-0.1.0[${PYTHON_USEDEP}]
+ dev-python/prometheus_client[${PYTHON_USEDEP}]
+ >=dev-python/send2trash-1.8.0[${PYTHON_USEDEP}]
+ >=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+ >=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+ >=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+
+ <dev-python/notebook-7[${PYTHON_USEDEP}]
+"
+
+# dev-python/nbval is missing impls
+BDEPEND="
+ test? (
+ dev-python/jupyter-server-terminals[${PYTHON_USEDEP}]
+ dev-python/pytest_jupyter[${PYTHON_USEDEP}]
+ dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+ dev-python/testpath[${PYTHON_USEDEP}]
+ )
+ doc? (
+ virtual/pandoc
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+ dev-python/sphinx-rtd-theme \
+ dev-python/nbsphinx \
+ dev-python/sphinxcontrib-github-alt \
+ dev-python/myst-parser \
+ dev-python/ipython_genutils
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p pytest_tornasync.plugin
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+ # move /usr/etc stuff to /etc
+ mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
