commit: 39b1f3e0df01d0fb9ba0916d6d7206070fb4a3be
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 10 06:44:14 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Feb 10 06:52:06 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=39b1f3e0
dev-python/hatchling: Bump to 1.13.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/hatchling/Manifest | 1 +
dev-python/hatchling/hatchling-1.13.0.ebuild | 77 ++++++++++++++++++++++++++++
2 files changed, 78 insertions(+)
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index f472955e43c3..1ddb0224582e 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1 +1,2 @@
DIST hatch-hatchling-v1.12.2.gh.tar.gz 381872 BLAKE2B
6290daca1f2d2cd4eb9479b2f34b782881651c0106008c8876c355e5f3aa12cdbd0168765fdc04dd7870f9b88d44cc1be8d3849b2f20393bf64bebe9dbf09dd9
SHA512
74404b3b5369f6a8350cbde9675de6d9d7a72aca721714d47d8c4052c341affed1ebb4f4caae96877c2ccf2c4bab29b8323643e2a3d7de67bfe5888f3a08cdca
+DIST hatch-hatchling-v1.13.0.gh.tar.gz 383610 BLAKE2B
0a3dc20f6c1c504c94c09897e23e6ade844318488093cf849e332cf08f7be178ddb3ae61d8ff01af93438c01216b056a3566e9d8758a0151e4d7498447a9524f
SHA512
fb14e1d088676dfc2b76dda207aa514232c3c5b8472d7332c0d53e0bd4dbd1d0e3bd1ac9f261f72e1a32610c565485f5e382fc7071e80066735a04eb8cade13e
diff --git a/dev-python/hatchling/hatchling-1.13.0.ebuild
b/dev-python/hatchling/hatchling-1.13.0.ebuild
new file mode 100644
index 000000000000..9b92d2a41c5b
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.13.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{9..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+ https://pypi.org/project/hatchling/
+ https://github.com/pypa/hatch/
+"
+SRC_URI="
+ https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+RDEPEND="
+ >=dev-python/editables-0.3[${PYTHON_USEDEP}]
+ >=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+ >=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+ ' 3.8 3.9 3.10)
+"
+BDEPEND="
+ ${RDEPEND}
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/atomicwrites[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ dev-python/platformdirs[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ dev-python/tomli-w[${PYTHON_USEDEP}]
+ dev-python/virtualenv[${PYTHON_USEDEP}]
+ ' "${PYTHON_TESTED[@]}")
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+ einfo "Skipping tests on ${EPYTHON}"
+ return
+ fi
+
+ local -x EPYTEST_DESELECT=(
+ # these run pip to install stuff
+ tests/backend/dep/test_core.py::test_dependency_found
+ tests/backend/dep/test_core.py::test_extra_met
+ tests/backend/dep/test_core.py::test_extra_no_dependencies
+ tests/backend/dep/test_core.py::test_extra_unmet
+ tests/backend/dep/test_core.py::test_unknown_extra
+ tests/backend/dep/test_core.py::test_version_unmet
+ )
+
+ # top-level "tests" directory contains tests both for hatch
+ # and hatchling
+ cd "${WORKDIR}/${MY_P}" || die
+ local -x PYTHONPATH="src:${PYTHONPATH}"
+ epytest tests/backend
+}
