commit: e520f0402fcfd545bdec7f5880a6275f52725d12
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 31 16:30:27 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan 31 16:58:00 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e520f040
dev-python/APScheduler: PEP517, py3.11
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/APScheduler/APScheduler-3.9.1-r1.ebuild | 58 ++++++++++++++++++++++
1 file changed, 58 insertions(+)
diff --git a/dev-python/APScheduler/APScheduler-3.9.1-r1.ebuild
b/dev-python/APScheduler/APScheduler-3.9.1-r1.ebuild
new file mode 100644
index 000000000000..662165451711
--- /dev/null
+++ b/dev-python/APScheduler/APScheduler-3.9.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="In-process task scheduler with Cron-like capabilities"
+HOMEPAGE="
+ https://github.com/agronholm/apscheduler/
+ https://pypi.org/project/APScheduler/
+"
+SRC_URI="mirror://pypi/A/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# imports pkg_resources
+RDEPEND="
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ >=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/tzlocal-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ <dev-python/sqlalchemy-2[${PYTHON_USEDEP}]
+ dev-python/tornado[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+ # disable test fixtures using external servers (mongodb, redis...)
+ # these fixtures are using markers in git master, so the patch
+ # should be no longer necessary with next major bump
+ "${FILESDIR}"/APScheduler-3.8.1-external-server-tests.patch
+)
+
+EPYTEST_DESELECT=(
+ tests/test_jobstores.py::test_repr_mongodbjobstore
+ tests/test_jobstores.py::test_repr_redisjobstore
+ tests/test_jobstores.py::test_repr_zookeeperjobstore
+)
+
+python_prepare_all() {
+ # suppress setuptools warning #797751
+ sed -e 's|^upload-dir|upload_dir|' -i setup.cfg || die
+ sed -e '/addopts/d' -i setup.cfg || die
+
+ distutils-r1_python_prepare_all
+}
