commit: 94d877eec96235d44b45defdfa1e4eb6498055cc
Author: Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 1 23:07:28 2022 +0000
Commit: Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Wed Nov 2 00:20:20 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94d877ee
media-libs/vulkan-loader: add 1.3.231
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>
media-libs/vulkan-loader/Manifest | 1 +
.../vulkan-loader/vulkan-loader-1.3.231.ebuild | 65 ++++++++++++++++++++++
2 files changed, 66 insertions(+)
diff --git a/media-libs/vulkan-loader/Manifest
b/media-libs/vulkan-loader/Manifest
index c114a7eaac7a..6a9df76390d9 100644
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1 +1,2 @@
DIST vulkan-loader-1.3.224.tar.gz 1594886 BLAKE2B
a2b548c1b2ce4b5a700dca2708fc628ebc6ae248b5c1750cc2fe33d24e3f8260007f1fd04f2f3f55984889708354ebebf21bcce73e24f1da23aba426718f053a
SHA512
e75f0d399703606fc89a08783c5cc9a542d7e14073039d63df4aac673d2b246a5c5b0ac4acab5e0f276b533c47645af11606de96460066fd70ccaa6de1888b37
+DIST vulkan-loader-1.3.231.tar.gz 1609720 BLAKE2B
0e6c2bdb6934502cd7f315636cf17dc0eeca7b990f8573944dcf5aec775272ce8c246efe51ee0395e0c2ed23c63a584be104d8a49a556c6d17e0fa66fda772cf
SHA512
07f1a8e7737d9609a138b4e9740f9c2228db1ac56f8ddbf3c1ec0ec3b745647002ba3af4725347941dae2feb63e7c33c9db5f14ab98d2f47dfd2181a559ba849
diff --git a/media-libs/vulkan-loader/vulkan-loader-1.3.231.ebuild
b/media-libs/vulkan-loader/vulkan-loader-1.3.231.ebuild
new file mode 100644
index 000000000000..873df8148a72
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.3.231.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Loader
+inherit flag-o-matic cmake-multilib toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+ EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git";
+ EGIT_SUBMODULES=()
+ inherit git-r3
+else
+
SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.tar.gz ->
${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+ S="${WORKDIR}"/${MY_PN}-sdk-${PV}
+fi
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader";
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+DEPEND="
+ ~dev-util/vulkan-headers-${PV}
+ wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+ X? (
+ x11-libs/libX11:=[${MULTILIB_USEDEP}]
+ x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+ )
+"
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+ # Integrated clang assembler doesn't work with x86 - Bug #698164
+ if tc-is-clang && [[ ${ABI} == x86 ]]; then
+ append-cflags -fno-integrated-as
+ fi
+
+ local mycmakeargs=(
+ -DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+ -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+ -DCMAKE_SKIP_RPATH=ON
+ -DBUILD_TESTS=OFF
+ -DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+ -DBUILD_WSI_XCB_SUPPORT=$(usex X)
+ -DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+ -DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+ )
+ cmake_src_configure
+}
+
+multilib_src_install() {
+ keepdir /etc/vulkan/icd.d
+
+ cmake_src_install
+}
+
+pkg_postinst() {
+ einfo "USE=demos has been dropped as per upstream packaging"
+ einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}
