[gentoo-commits] repo/gentoo:master commit in: dev-python/dask/

[Michał Górny]

commit:     7db9584ac73efa962dc25a2c40e6f851203c6fe4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 23 04:44:17 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul 23 06:22:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7db9584a

dev-python/dask: Bump to 2022.7.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dask/Manifest             |  1 +
 dev-python/dask/dask-2022.7.1.ebuild | 58 ++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index c1007f744d5e..ca1aa5e3e06a 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -1,2 +1,3 @@
 DIST dask-2022.6.1.gh.tar.gz 8729249 BLAKE2B 
211beeb3960569aa1cb68a4fd9b261a417297de5dc406d50bc54342239227ea01e2158b618bd889862a7eff8bb01bb43d098937bb3911f088250957caa672d04
 SHA512 
6e06b63dd5c7f1d7c6c7dce867ffa42b956023b313b25245a339f698b06bea17a03cc4ead9bd5aef8ddf081750cad4df4b6b2972038315c89585221382c9e95c
 DIST dask-2022.7.0.gh.tar.gz 8748843 BLAKE2B 
ae0e63c883e6542aefd29a619168b1e86e9b20d43e7966ecb8a92a90b72952acd7e08ce53fdbc146b47bcb7f65190f2d0cbe19966c52f94b0d52eb63e53778d9
 SHA512 
11fe292134dac14e30068b98d88e622af2941b7fffa2c667b39b87e4d28ac6388001e18a8628bd22bbd48a2a10ee707dc25618a960a401e40cb73b2231fd2dfc
+DIST dask-2022.7.1.gh.tar.gz 8749841 BLAKE2B 
9c4db1adbfd9ea796db10855f98b972104415e66d5d01800e139d9475ceaedb850867a47d8af8e538856bcf21f805d6f24146a8407968e96c0084f81ce5e323d
 SHA512 
459c20cdb8da523020483212cc48fdf0830915ce6cbd48511ccb02e3a1a5c4c8e1ce9bafb09e1288ec7f89d9dc8da36cd7fe75da1441cb3e5b31521720fd0708

diff --git a/dev-python/dask/dask-2022.7.1.ebuild 
b/dev-python/dask/dask-2022.7.1.ebuild
new file mode 100644
index 000000000000..ce906c8679d6
--- /dev/null
+++ b/dev-python/dask/dask-2022.7.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="
+       https://www.dask.org/
+       https://github.com/dask/dask/
+       https://pypi.org/project/dask/
+"
+SRC_URI="
+       https://github.com/dask/dask/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+       >=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+       >=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+       >=dev-python/numpy-1.15.1[${PYTHON_USEDEP}]
+       >=dev-python/pandas-0.25.0[${PYTHON_USEDEP}]
+       >=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+       >=dev-python/partd-0.3.10[${PYTHON_USEDEP}]
+       dev-python/psutil[${PYTHON_USEDEP}]
+       >=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+       >=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       dev-python/toolz[${PYTHON_USEDEP}]
+       test? (
+               dev-python/moto[${PYTHON_USEDEP}]
+               dev-python/numexpr[${PYTHON_USEDEP}]
+               dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+               dev-python/scipy[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+       # another test relying on -Werror
+       "dask/array/tests/test_overlap.py::test_map_overlap_no_depth[None]"
+       # TODO
+       dask/array/tests/test_reductions.py::test_mean_func_does_not_warn
+       dask/tests/test_config.py::test__get_paths
+)
+
+python_test() {
+       epytest -p no:flaky -m "not network"
+}