commit: ebf8c3ffbe47766664828fe2d21c6ea11a5dc19b
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Jun 19 17:20:41 2022 +0000
Commit: Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Sun Jun 19 18:50:19 2022 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=ebf8c3ff
net-voip/gnome-calls: EAPI 7 -> 8
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
net-voip/gnome-calls/gnome-calls-42.0-r1.ebuild | 75 +++++++++++++++++++++++++
net-voip/gnome-calls/gnome-calls-42.0.ebuild | 62 --------------------
2 files changed, 75 insertions(+), 62 deletions(-)
diff --git a/net-voip/gnome-calls/gnome-calls-42.0-r1.ebuild
b/net-voip/gnome-calls/gnome-calls-42.0-r1.ebuild
new file mode 100644
index 000000000..13cf60c4a
--- /dev/null
+++ b/net-voip/gnome-calls/gnome-calls-42.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson gnome2-utils virtualx xdg
+
+MY_PN="${PN#gnome-}"
+MY_P="${MY_PN}-${PV}"
+LCU_COMMIT="acfbb136bbf74514e0b9801ce6c1e8acf36350b6"
+DESCRIPTION="Phone dialer and call handler"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/calls";
+GITLAB="https://gitlab.gnome.org";
+SRC_URI="
+ ${GITLAB}/GNOME/${MY_PN}/-/archive/${PV}/${MY_P}.tar.gz
+
${GITLAB}/World/Phosh/libcall-ui/-/archive/${LCU_COMMIT}/libcall-ui-${LCU_COMMIT}.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+DEPEND="
+ app-crypt/libsecret[introspection(+),vala(+)]
+ dev-libs/feedbackd[introspection(+),vala(+)]
+ dev-libs/folks:=
+ dev-libs/glib:2
+ dev-libs/gom[introspection(+)]
+ dev-libs/libgee:0.8=[introspection(+)]
+ dev-libs/libpeas
+ gnome-extra/evolution-data-server:=[vala(+)]
+ >=gui-libs/libhandy-1.0.0:1[introspection(+),vala(+)]
+ media-libs/gstreamer:1.0[introspection(+)]
+ >=media-sound/callaudiod-0.0.5
+ net-libs/sofia-sip
+ >=net-misc/modemmanager-1.12.0:=[introspection(+)]
+ x11-libs/gtk+:3
+"
+RDEPEND="${DEPEND}
+ virtual/secret-service
+"
+BDEPEND="
+ $(vala_depend)
+ dev-libs/gobject-introspection
+ dev-libs/protobuf
+ dev-util/wayland-scanner
+"
+
+src_unpack() {
+ default
+
+ rm -r "${S}"/subprojects/libcall-ui || die
+ mv "${WORKDIR}"/libcall-ui-${LCU_COMMIT} "${S}"/subprojects/libcall-ui
|| die
+}
+
+src_prepare() {
+ default
+ vala_setup
+}
+
+src_test() {
+ virtx meson_src_test
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
diff --git a/net-voip/gnome-calls/gnome-calls-42.0.ebuild
b/net-voip/gnome-calls/gnome-calls-42.0.ebuild
deleted file mode 100644
index f26b99e44..000000000
--- a/net-voip/gnome-calls/gnome-calls-42.0.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-VALA_USE_DEPEND="vapigen"
-
-inherit vala meson gnome2-utils xdg
-
-LCU_COMMIT="acfbb136bbf74514e0b9801ce6c1e8acf36350b6"
-DESCRIPTION="Phone dialer and call handler"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/calls";
-SRC_URI="
- https://gitlab.gnome.org/GNOME/calls/-/archive/${PV}/calls-${PV}.tar.gz
-
https://gitlab.gnome.org/World/Phosh/libcall-ui/-/archive/${LCU_COMMIT}/libcall-ui-${LCU_COMMIT}.tar.gz
-"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-IUSE="+introspection +vala"
-REQUIRED_USE="vala? ( introspection )"
-
-DEPEND="
- dev-libs/feedbackd
- >=gui-libs/libhandy-1.0.0
- dev-libs/folks
- dev-libs/gom
- dev-libs/libpeas
- >=net-misc/modemmanager-1.12.0
- >=media-sound/callaudiod-0.0.5
- gnome-extra/evolution-data-server
- net-libs/sofia-sip
- dev-libs/protobuf
- "
-RDEPEND="${DEPEND}"
-BDEPEND="
- vala? ( $(vala_depend) )
- dev-util/meson
- dev-libs/gobject-introspection
- dev-util/wayland-scanner
-"
-
-S="${WORKDIR}/calls-${PV}"
-
-src_prepare() {
- default
- eapply_user
- use vala && vala_src_prepare
-
- rm -r "${S}"/subprojects/libcall-ui || die
- mv "${WORKDIR}"/libcall-ui-"${LCU_COMMIT}"
"${S}"/subprojects/libcall-ui || die
-}
-
-pkg_postinst() {
- xdg_pkg_postinst
- gnome2_schemas_update
-}
-
-pkg_postrm() {
- xdg_pkg_postrm
- gnome2_schemas_update
-}
