commit: 55eb93f3394b908c89e76fe69c0f5c92405f0eb9
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue May 31 07:19:21 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May 31 07:19:43 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55eb93f3
dev-python/lxml: add 4.9.0
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-python/lxml/Manifest | 1 +
dev-python/lxml/lxml-4.9.0.ebuild | 108 ++++++++++++++++++++++++++++++++++++++
2 files changed, 109 insertions(+)
diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index 1bbee16e748c..fd65bdf74d3c 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -1 +1,2 @@
DIST lxml-4.8.0.tar.gz 959376 BLAKE2B
a40be5e058153e1dc3f8501b645b0211f4498928ed71b161df54a67501356e9968064401b6d17e17dc8d62223b29e794eaa2bee7ff78ffee203d9f9a22f3e1c2
SHA512
bbcd8ea001cfa2820dcac4e00de6ded81700b2f0bd4a58bcdd4da05a19a107f57cd56280c4838fe19ee7ecd6be105878bf8c2f1c0e5111899c4ad1a2ba03537f
+DIST lxml-4.9.0.gh.tar.gz 960503 BLAKE2B
5b4c6c3c7c5f14167fa209700207a4d0bc7fbe67214060258e0474c11885f1bb0a6b57cc02d0df40f035670d14552ebc66acda3c184e77840377cb3f47187b18
SHA512
e85036a96a78da092d7d77dfb482ca00094811d085076bd2a1fe6f5cb31ac9ba8273a1193b5de8af7b4551b4deb41add83db450de8186c0567fcb4522a8da803
diff --git a/dev-python/lxml/lxml-4.9.0.ebuild
b/dev-python/lxml/lxml-4.9.0.ebuild
new file mode 100644
index 000000000000..cc4c7423d460
--- /dev/null
+++ b/dev-python/lxml/lxml-4.9.0.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1 optfeature toolchain-funcs
+
+DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
+HOMEPAGE="
+ https://lxml.de/
+ https://pypi.org/project/lxml/
+ https://github.com/lxml/lxml
+"
+SRC_URI="https://github.com/lxml/lxml/archive/${P}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/lxml-${P}
+
+LICENSE="BSD ElementTree GPL-2 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos
~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples +threads test"
+RESTRICT="!test? ( test )"
+
+# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
+DEPEND="
+ >=dev-libs/libxml2-2.9.12-r2
+ >=dev-libs/libxslt-1.1.28"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="
+ virtual/pkgconfig
+ dev-python/cython[${PYTHON_USEDEP}]
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+ ')
+ )
+ test? (
+ dev-python/cssselect[${PYTHON_USEDEP}]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-4.6.0-tests-pypy.patch
+)
+
+python_check_deps() {
+ use doc || return 0
+ has_version -b "dev-python/docutils[${PYTHON_USEDEP}]" &&
+ has_version -b "dev-python/pygments[${PYTHON_USEDEP}]" &&
+ has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+ has_version -b "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+ # avoid replacing PYTHONPATH in tests.
+ sed -i -e '/sys\.path/d' test.py || die
+
+ # don't use some random SDK on Darwin
+ sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
+ setupinfo.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile() {
+ tc-export PKG_CONFIG
+ distutils-r1_python_compile
+}
+
+python_compile_all() {
+ use doc && emake html
+}
+
+python_test() {
+ local dir=${BUILD_DIR}/test$(python_get_sitedir)/lxml
+ local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+ cp -al "${BUILD_DIR}"/{install,test} || die
+ cp -al src/lxml/tests "${dir}/" || die
+ cp -al src/lxml/html/tests "${dir}/html/" || die
+ ln -rs "${S}"/doc "${dir}"/../../ || die
+
+ "${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails
with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use doc; then
+ local DOCS=( README.rst *.txt doc/*.txt )
+ local HTML_DOCS=( doc/html/. )
+ fi
+ if use examples; then
+ dodoc -r samples
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Support for BeautifulSoup as a parser backend"
dev-python/beautifulsoup4
+ optfeature "Translates CSS selectors to XPath 1.0 expressions"
dev-python/cssselect
+}
