commit: 28d84da8caf69a31ba9a3f7a7ecae1533e4f4ae7
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 11 09:05:42 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 11 09:17:20 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28d84da8
dev-python/pexpect: Switch to PEP517 build
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pexpect/pexpect-4.8.0-r3.ebuild | 50 ++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
diff --git a/dev-python/pexpect/pexpect-4.8.0-r3.ebuild
b/dev-python/pexpect/pexpect-4.8.0-r3.ebuild
new file mode 100644
index 000000000000..4fbf5faed1a0
--- /dev/null
+++ b/dev-python/pexpect/pexpect-4.8.0-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for spawning child apps and responding to expected
patterns"
+HOMEPAGE="
+ https://pexpect.readthedocs.io/
+ https://pypi.org/project/pexpect/
+ https://github.com/pexpect/pexpect/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/ptyprocess-0.5[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-sphinx-3.patch
+ "${FILESDIR}"/${P}-fix-PS1.patch
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc
+
+src_test() {
+ # workaround new readline defaults
+ echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+ local -x INPUTRC="${T}"/inputrc
+ distutils-r1_src_test
+}
+
+python_install_all() {
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+ distutils-r1_python_install_all
+}
