[gentoo-commits] gentoo-x86 commit in net-analyzer/argus-clients: argus-clients-3.0.8.ebuild ChangeLog argus-clients-3.0.8_rc6.ebuild

[Jeroen Roovers (jer)]

jer         14/10/12 09:18:28

  Modified:             ChangeLog
  Added:                argus-clients-3.0.8.ebuild
  Removed:              argus-clients-3.0.8_rc6.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with 
key A792A613)

Revision  Changes    Path
1.70                 net-analyzer/argus-clients/ChangeLog

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus-clients/ChangeLog?rev=1.70&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus-clients/ChangeLog?rev=1.70&content-type=text/plain
diff : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus-clients/ChangeLog?r1=1.69&r2=1.70

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/argus-clients/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog   10 Jul 2014 19:03:45 -0000      1.69
+++ ChangeLog   12 Oct 2014 09:18:28 -0000      1.70
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/argus-clients
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus-clients/ChangeLog,v 1.69 
2014/07/10 19:03:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus-clients/ChangeLog,v 1.70 
2014/10/12 09:18:28 jer Exp $
+
+*argus-clients-3.0.8 (12 Oct 2014)
+
+  12 Oct 2014; Jeroen Roovers <j...@gentoo.org> 
-argus-clients-3.0.8_rc6.ebuild,
+  +argus-clients-3.0.8.ebuild:
+  Version bump.
 
 *argus-clients-3.0.8_rc6 (10 Jul 2014)
 



1.1                  net-analyzer/argus-clients/argus-clients-3.0.8.ebuild

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus-clients/argus-clients-3.0.8.ebuild?rev=1.1&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus-clients/argus-clients-3.0.8.ebuild?rev=1.1&content-type=text/plain

Index: argus-clients-3.0.8.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: 
/var/cvsroot/gentoo-x86/net-analyzer/argus-clients/argus-clients-3.0.8.ebuild,v 
1.1 2014/10/12 09:18:28 jer Exp $

EAPI=5
inherit autotools eutils toolchain-funcs

DESCRIPTION="Clients for net-analyzer/argus"
HOMEPAGE="http://www.qosient.com/argus/";
SRC_URI="http://qosient.com/argus/dev/${P}.tar.gz";

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug ft geoip mysql sasl tcpd"

MY_CDEPEND="
        net-analyzer/rrdtool[perl]
        net-libs/libpcap
        sys-libs/ncurses
        sys-libs/readline
        sys-libs/zlib
        ft? ( net-analyzer/flow-tools )
        geoip? ( dev-libs/geoip )
        mysql? ( virtual/mysql )
        sasl? ( dev-libs/cyrus-sasl )
"

RDEPEND="
        ${MY_CDEPEND}
"

DEPEND="
        ${MY_CDEPEND}
        sys-devel/bison
        sys-devel/flex
        virtual/pkgconfig
"

src_prepare() {
        epatch \
                
"${FILESDIR}"/${PN}-3.0.4.1-disable-tcp-wrappers-automagic.patch \
                "${FILESDIR}"/${PN}-3.0.7.21-curses-readline.patch

        sed -i -e 's| ar | $(AR) |g' common/Makefile.in || die
        tc-export AR RANLIB

        eautoreconf
}

src_configure() {
        use debug && touch .debug
        econf \
                $(use_with ft libft) \
                $(use_with geoip GeoIP /usr/) \
                $(use_with sasl) \
                $(use_with tcpd wrappers) \
                $(use_with mysql)
}

src_compile() {
        # racurses uses both libncurses and libtinfo, if present
        emake \
                CCOPT="${CFLAGS} ${LDFLAGS}" \
                RANLIB=$(tc-getRANLIB) \
                CURSESLIB="$( $(tc-getPKG_CONFIG) --libs ncurses)"
}

src_install() {
        dobin bin/ra*
        dodoc ChangeLog CREDITS README CHANGES
        doman man/man{1,5}/*
}