[gentoo-commits] gentoo-x86 commit in dev-python/llvmpy: llvmpy-0.12.7.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/08/13 00:06:31

  Modified:             ChangeLog
  Added:                llvmpy-0.12.7.ebuild
  Log:
  bump; add pypy support, fix fix to qa build issue, thanks to Arfrever for the 
fix
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 
0xB8072B0D)

Revision  Changes    Path
1.8                  dev-python/llvmpy/ChangeLog

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/llvmpy/ChangeLog?rev=1.8&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/llvmpy/ChangeLog?rev=1.8&content-type=text/plain
diff : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/llvmpy/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/llvmpy/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog   16 Jun 2014 08:58:07 -0000      1.7
+++ ChangeLog   13 Aug 2014 00:06:30 -0000      1.8
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/llvmpy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/ChangeLog,v 1.7 
2014/06/16 08:58:07 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/ChangeLog,v 1.8 
2014/08/13 00:06:30 idella4 Exp $
+
+*llvmpy-0.12.7 (12 Aug 2014)
+
+  12 Aug 2014; Ian Delaney <idel...@gentoo.org> +llvmpy-0.12.7.ebuild:
+  bump; add pypy support, fix fix to qa build issue, thanks to Arfrever for the
+  fix
 
 *llvmpy-0.12.6 (16 Jun 2014)
 



1.1                  dev-python/llvmpy/llvmpy-0.12.7.ebuild

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/llvmpy/llvmpy-0.12.7.ebuild?rev=1.1&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/llvmpy/llvmpy-0.12.7.ebuild?rev=1.1&content-type=text/plain

Index: llvmpy-0.12.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/llvmpy/llvmpy-0.12.7.ebuild,v 1.1 
2014/08/13 00:06:30 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} pypy )

inherit distutils-r1

DESCRIPTION="Python wrapper around the llvm C++ library"
HOMEPAGE="http://llvmpy.org/";
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc"

# fails with llvm-3.4
RDEPEND="=sys-devel/llvm-3.3*:=[multitarget]"
DEPEND="${RDEPEND}
        doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
# Usual; req'd for tests
DISTUTILS_IN_SOURCE_BUILD=1

PATCHES=( "${FILESDIR}"/${PN}-0.12.2-return-type.patch )

python_compile_all() {
        use doc && emake -C docs html
}

python_compile() {
        if ! python_is_python3; then
                local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
                export CXXFLAGS
        fi
        distutils-r1_python_compile
}

python_test() {
        cd "${BUILD_DIR}"/lib* || die
        ${PYTHON} -c "import llvm; llvm.test()" || die
}

python_install() {
        if ! python_is_python3; then
                local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
                export CXXFLAGS
        fi
        distutils-r1_python_install
}

python_install_all() {
        use doc && local HTML_DOCS=( docs/_build/html )
        distutils-r1_python_install_all
}