[gentoo-commits] repo/gentoo:master commit in: dev-python/pythonmagick/

[Mike Gilbert]

commit:     0200bbefa1b4457c77cd05677825563b19f263c7
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Sun May 28 02:24:11 2017 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun May 28 02:24:11 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0200bbef

dev-python/pythonmagick: bump to 0.9.17

Package-Manager: Portage-2.3.6_p1, Repoman-2.3.2_p69

 dev-python/pythonmagick/Manifest                   |  1 +
 dev-python/pythonmagick/pythonmagick-0.9.17.ebuild | 62 ++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/pythonmagick/Manifest b/dev-python/pythonmagick/Manifest
index 491ed84b785..d49a8cf4db7 100644
--- a/dev-python/pythonmagick/Manifest
+++ b/dev-python/pythonmagick/Manifest
@@ -1 +1,2 @@
 DIST PythonMagick-0.9.14.tar.xz 270488 SHA256 
42fc1fc0def8a9fa0af282c1ba330831d7ba310b5d7dc7b0f03c0536a26b93ba SHA512 
a09696d8ebe3c8d38a9148e6f812c149d34fbe1dbe64ecf07b43e153b3c7fd97738491818dec348072ff96e54ac0eddd17eff75c5cef8df21a8a89f58e918e98
 WHIRLPOOL 
dcdd3b78c9b425cefbc8f05b0e3af9be9fa217c5175788ce75d44c985a86fb7c73d85d0e6b41e344685d78db2b66a9ea820b1f30a7fd8e30290e08b22fd20d71
+DIST PythonMagick-0.9.17.tar.xz 271844 SHA256 
34aeaab51268432c25f68b36fbd5daca97c0d564cb61c761b018731516d0711e SHA512 
e50e5e0d27f2dc8ccd1b251a0311ecca825423b34e85a257bfce42696c4a285977ffb8bade487fb8a3a4f8cad26d0a41fc067b172b733d0c48e951a27badded7
 WHIRLPOOL 
cacbbc04ce0d6ec32ef27e9829a49e88841073ca92b16f636d8111cdd862f163aee77c3191bcaf4b18bc699514fb61e616e8b5ce9960c5a4dc78aa6f78f3711c

diff --git a/dev-python/pythonmagick/pythonmagick-0.9.17.ebuild 
b/dev-python/pythonmagick/pythonmagick-0.9.17.ebuild
new file mode 100644
index 00000000000..ffdccbf8653
--- /dev/null
+++ b/dev-python/pythonmagick/pythonmagick-0.9.17.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit python-r1
+
+MY_PN="PythonMagick"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for ImageMagick"
+HOMEPAGE="http://www.imagemagick.org/script/api.php";
+SRC_URI="mirror://imagemagick/python/${MY_P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+       >=dev-libs/boost-1.48[python,${PYTHON_USEDEP}]
+       >=media-gfx/imagemagick-6.9.1
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+       default
+       python_copy_sources
+}
+
+src_configure() {
+       python_configure() {
+               if ! python_is_python3; then
+                       local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+               fi
+               econf \
+                       --disable-static \
+                       --with-boost-python=boost_python-${EPYTHON#python}
+       }
+
+       python_foreach_impl run_in_build_dir python_configure
+}
+
+src_compile() {
+       python_foreach_impl run_in_build_dir emake
+}
+
+src_test() {
+       python_foreach_impl run_in_build_dir emake check
+}
+
+src_install() {
+       python_foreach_impl run_in_build_dir emake DESTDIR="${D}" install
+       einstalldocs
+       find "${D}" -name '*.la' -delete || die
+}