[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-restful/

[Tiziano Müller]

commit:     37235adcb5836ae5dae998e98777d74c31f801a0
Author:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
AuthorDate: Tue Mar 15 21:54:57 2016 +0000
Commit:     Tiziano Müller <dev-zero <AT> gentoo <DOT> org>
CommitDate: Tue Mar 15 21:55:48 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=37235adc

dev-python/flask-restful: rev-bump for py-3.5 support and EAPI-6

Package-Manager: portage-2.2.28

 .../flask-restful/flask-restful-0.3.5-r1.ebuild    | 51 ++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-python/flask-restful/flask-restful-0.3.5-r1.ebuild 
b/dev-python/flask-restful/flask-restful-0.3.5-r1.ebuild
new file mode 100644
index 0000000..5b6f387
--- /dev/null
+++ b/dev-python/flask-restful/flask-restful-0.3.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple framework for creating REST APIs"
+HOMEPAGE="http://flask-restful.readthedocs.org/ 
https://github.com/twilio/flask-restful/";
+SRC_URI="https://github.com/twilio/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples paging test"
+
+RDEPEND="
+       >=dev-python/aniso8601-0.82[${PYTHON_USEDEP}]
+       >=dev-python/flask-0.8[${PYTHON_USEDEP}]
+       >=dev-python/six-1.3.0[${PYTHON_USEDEP}]
+       dev-python/pytz[${PYTHON_USEDEP}]
+       paging? ( >=dev-python/pycrypto-2.6[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       dev-python/sphinx[${PYTHON_USEDEP}]
+       test? (
+               dev-python/mock[${PYTHON_USEDEP}]
+               dev-python/nose[${PYTHON_USEDEP}]
+               dev-python/pycrypto[${PYTHON_USEDEP}]
+       )
+"
+
+python_test() {
+       nosetests -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_compile_all() {
+       cd docs || die
+       emake man $(usex doc html "")
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/_build/html/. )
+       use examples && dodoc -r examples
+       local DOCS=( AUTHORS.md CHANGES.md CONTRIBUTING.md README.md )
+
+       doman docs/_build/man/*
+       distutils-r1_python_install_all
+}