commit: 7701187a51891cb638ae55c40dbc1ac47f1db9af
Author: Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 22 11:12:10 2026 +0000
Commit: Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
CommitDate: Sun Feb 22 11:12:10 2026 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7701187a
dev-python/notebook: enable py3.14 on 7.4.x
Signed-off-by: Nowa Ammerlaan <nowa <AT> gentoo.org>
dev-python/notebook/notebook-7.4.7-r1.ebuild | 63 ++++++++++++++++++++++++++++
1 file changed, 63 insertions(+)
diff --git a/dev-python/notebook/notebook-7.4.7-r1.ebuild
b/dev-python/notebook/notebook-7.4.7-r1.ebuild
new file mode 100644
index 000000000000..e8754b1a70a0
--- /dev/null
+++ b/dev-python/notebook/notebook-7.4.7-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="
+ https://jupyter.org/
+ https://github.com/jupyter/notebook/
+ https://pypi.org/project/notebook/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+ >=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+ <dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+ >=dev-python/jupyterlab-4.4.9[${PYTHON_USEDEP}]
+ <dev-python/jupyterlab-4.5[${PYTHON_USEDEP}]
+ >=dev-python/jupyterlab-server-2.27.1[${PYTHON_USEDEP}]
+ <dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+ >=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+ <dev-python/notebook-shim-0.3[${PYTHON_USEDEP}]
+ >=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+ >=dev-python/jupyterlab-4.4[${PYTHON_USEDEP}]
+ <dev-python/jupyterlab-4.5[${PYTHON_USEDEP}]
+ test? (
+ dev-python/ipykernel[${PYTHON_USEDEP}]
+ dev-python/nbval[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( pytest-{console-scripts,jupyter,timeout,tornasync} )
+distutils_enable_tests pytest
+
+python_install_all() {
+ distutils-r1_python_install_all
+ mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+}
