[gentoo-commits] repo/gentoo:master commit in: dev-libs/qcoro/

[Andreas Sturmlechner]

commit:     c6467b8d3d09146dd71e8d928005bdebbd148542
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 14 21:30:48 2026 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb 14 21:30:48 2026 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c6467b8d

dev-libs/qcoro: add 0.13.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/qcoro/Manifest            |  1 +
 dev-libs/qcoro/qcoro-0.13.0.ebuild | 60 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/qcoro/Manifest b/dev-libs/qcoro/Manifest
index 1d1441ad0280..641ce9ed9660 100644
--- a/dev-libs/qcoro/Manifest
+++ b/dev-libs/qcoro/Manifest
@@ -1 +1,2 @@
 DIST qcoro-0.12.0.tar.gz 161468 BLAKE2B 
a7b5f203e227dc2e5dd9f74ccc72b3ab2972803e613a1fede5c597e97e281e3817eff8f088b3abba82d96815e296e1106a324f33078b45607a13de31797bd154
 SHA512 
f1da90c4a9bec5f52ec9f40caa30c8465658c6ff005c6c7e89aeb97acc4aefd5e34030493b7e51313a6d2b3fc59114f6ed6751f31f1c132ece173f0e22154c37
+DIST qcoro-0.13.0.tar.gz 163436 BLAKE2B 
9b1df26c9b6ad9ea2309c94a3bc9ff0e88b7244c085569396e63b615ebd8136a20cc366e5f3d4638d212418cf0630ce49544f2907a11d35df03a96a38ec90b46
 SHA512 
bdb7a4080a0baa0c86765b181b9126cb3276c344d402b96683c984af559bd9af834a1e8bc9a63239eb76d0d102430ddfa8262cc72f6962f9d202b5e9a46ffce0

diff --git a/dev-libs/qcoro/qcoro-0.13.0.ebuild 
b/dev-libs/qcoro/qcoro-0.13.0.ebuild
new file mode 100644
index 000000000000..9112d915b812
--- /dev/null
+++ b/dev-libs/qcoro/qcoro-0.13.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == *9999* ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/danvratil/${PN}";
+else
+       
SRC_URI="https://github.com/danvratil/${PN}/archive/refs/tags/v${PV}.tar.gz -> 
${P}.tar.gz"
+       KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="C++ Coroutine Library for Qt"
+HOMEPAGE="https://qcoro.dvratil.cz/ https://github.com/danvratil/qcoro";
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="dbus examples +network qml test websockets"
+
+REQUIRED_USE="examples? ( network )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       dev-qt/qtbase:6[dbus?,network?]
+       qml? (
+               dev-qt/qtbase:6[gui]
+               dev-qt/qtdeclarative:6=
+       )
+       websockets? ( dev-qt/qtwebsockets:6 )
+"
+DEPEND="${RDEPEND}
+       examples? ( dev-qt/qtbase:6[concurrent,network,widgets] )
+       test? ( dev-qt/qtbase:6[concurrent] )
+"
+
+src_configure() {
+       local mycmakeargs=(
+               -DUSE_QT_VERSION=6
+               -DQCORO_BUILD_EXAMPLES=$(usex examples)
+               -DQCORO_WITH_QTDBUS=$(usex dbus)
+               -DQCORO_WITH_QTNETWORK=$(usex network)
+               -DQCORO_WITH_QML=$(usex qml)
+               -DQCORO_WITH_QTQUICK=$(usex qml)
+               -DQCORO_WITH_QTTEST=ON
+               -DBUILD_TESTING=$(usex test)
+               -DQCORO_WITH_QTWEBSOCKETS=$(usex websockets)
+       )
+       cmake_src_configure
+}
+
+src_install() {
+       if use examples; then
+               docinto examples
+               dodoc -r examples/*
+       fi
+       cmake_src_install
+}