commit: 204bf02a2af2763628d8f80c2eb9222c531ee330
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 5 03:50:41 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Sep 5 04:10:07 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=204bf02a
dev-python/qiskit: Bump to 2.2.0_rc1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/qiskit/Manifest | 2 +
dev-python/qiskit/qiskit-2.2.0_rc1.ebuild | 109 ++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/dev-python/qiskit/Manifest b/dev-python/qiskit/Manifest
index 9a331227f027..3f8ac4f9bf78 100644
--- a/dev-python/qiskit/Manifest
+++ b/dev-python/qiskit/Manifest
@@ -3,3 +3,5 @@ DIST qiskit-2.1.1.gh.tar.gz 7095152 BLAKE2B
fa611f4a5e772ba66bc58bc2832f6779dee5
DIST qiskit-2.1.2.gh.tar.gz 7100760 BLAKE2B
01f5789f20d1c73e73000ec87579981380d201b4d614dbfd7974d603c031de2a567e42c41f4552442805eb38b729784442a1e04e36054ba0c0a44a68b7410ad4
SHA512
a2e435f2523f538c922c868bf1fb303143f2efe4f3f70fe286d25fe467c454888f4fe7dc81b94e30e134e15446c6f3364a9ee932b5229952cb178e5db019ac1d
DIST qiskit-2.2.0b1-crates.tar.xz 16206228 BLAKE2B
2b654513fb78ae35e9179c094ea0ff05bafbd3ae226b6665034ad396c64ccf6a7d539a5e89a2815a241fe4a081b09cd43fd5779b0854ad6638c5f0a9b2bed7c7
SHA512
6a1550163808579adeaff9524fd494c153524d1780f459629943d95c0e712c310b8c0cf0325497c47caacf5a08ee0cdbe09c42e40329b305953aee2fa147b349
DIST qiskit-2.2.0b1.gh.tar.gz 7242652 BLAKE2B
ab708fcf06294ad3d218768ebde618d43efe23460ea4ba52ceacee1bb562c331e356c1620fdebb2c8b6eb265e84cbe4a258bcbec9474112c891a8db6e3262fac
SHA512
b98e04655cf6ebc9a3591a8fa50c1afdc653bb352ea91ce93f6bcda311cedb450da1947785d5b68088a04a0fa295c5df6358b4b3fe67d89d47e242d4d606442a
+DIST qiskit-2.2.0rc1-crates.tar.xz 16224208 BLAKE2B
5e218dd807216b0164680c9d0be0f8ca821ddd0d959a3401f3613f5264a35d4fd6d0c9c99fa55d6875606a9a956e5e6639cdc5ed0060dca2cf8ea8739e1fd608
SHA512
fb0fb3bdcfae60fe045c8214dc22619b15d961e169b9f28d3036b29d001bfe1fde07c33c20250088707502feebdc1d43f2d4d215353b562d3d4d553fae26099d
+DIST qiskit-2.2.0rc1.gh.tar.gz 7315424 BLAKE2B
c89dc4fcfbe316b6f79f714f889a9b4a9e10a6c86e3c31ae557d94305826024bb04a3c1f6f25faec4e4b19deab6c004752d1ee9066562a46cc2a0c1951c0970e
SHA512
1742b4e73eda2d8d6eca6a5f33bae360a084c2debbbbc441a4ab8036a1ead76b64850b949ec1dd4db3b7109951817a6a6dce7e4655d7f77d728c7bdb97545428
diff --git a/dev-python/qiskit/qiskit-2.2.0_rc1.ebuild
b/dev-python/qiskit/qiskit-2.2.0_rc1.ebuild
new file mode 100644
index 000000000000..1d81bbac269a
--- /dev/null
+++ b/dev-python/qiskit/qiskit-2.2.0_rc1.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+CRATES=""
+RUST_MIN_VER="1.84.0"
+
+inherit cargo distutils-r1
+
+MY_P=${P/_}
+CRATE_PV=2.2.0rc1
+DESCRIPTION="An open-source SDK for working with quantum computers"
+HOMEPAGE="
+ https://github.com/Qiskit/qiskit/
+ https://pypi.org/project/qiskit/
+"
+SRC_URI="
+ https://github.com/Qiskit/qiskit/archive/${PV/_}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+ ${CARGO_CRATE_URIS}
+
https://github.com/gentoo-crate-dist/qiskit/releases/download/${CRATE_PV/_}/${PN}-${CRATE_PV}-crates.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+="
+ Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 MIT MPL-2.0
+ Unicode-3.0 ZLIB
+"
+SLOT="0"
+IUSE="+visualization"
+
+RDEPEND="
+ >=dev-python/dill-0.3[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+ >=dev-python/python-constraint-1.4[${PYTHON_USEDEP}]
+ >=dev-python/rustworkx-0.15.0[${PYTHON_USEDEP}]
+ >=dev-python/scipy-1.5[${PYTHON_USEDEP}]
+ >=dev-python/stevedore-3.0.0[${PYTHON_USEDEP}]
+ visualization? (
+ >=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
+ dev-python/pydot[${PYTHON_USEDEP}]
+ >=dev-python/pillow-4.2.1[${PYTHON_USEDEP}]
+ >=dev-python/pylatexenc-1.4[${PYTHON_USEDEP}]
+ >=dev-python/seaborn-0.9.0[${PYTHON_USEDEP}]
+ >=dev-python/symengine-0.11.0[${PYTHON_USEDEP}]
+ >=dev-python/sympy-1.3[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ >=dev-python/cython-0.27.1[${PYTHON_USEDEP}]
+ test? (
+ app-text/poppler[png]
+ >=dev-python/ddt-1.4.4[${PYTHON_USEDEP}]
+ >=dev-python/networkx-2.2[${PYTHON_USEDEP}]
+ >=dev-python/qiskit-aer-0.14[${PYTHON_USEDEP}]
+ >=dev-python/scikit-learn-0.20.0[${PYTHON_USEDEP}]
+ )
+"
+
+# Files built without CFLAGS/LDFLAGS, acceptable for rust
+QA_FLAGS_IGNORED="
+ usr/lib.*/py.*/site-packages/qiskit/_accelerate.*.so
+ usr/lib.*/py.*/site-packages/qiskit/_qasm2.*.so
+"
+
+EPYTEST_PLUGINS=( hypothesis )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # strip forcing -Werror from tests that also leaks to other packages
+ sed -i -e '/filterwarnings.*error/d' test/utils/base.py || die
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
test/python/circuit/test_equivalence.py::TestEquivalenceLibraryVisualization::test_equivalence_draw
+
test/python/transpiler/test_unitary_synthesis_plugin.py::TestUnitarySynthesisPlugin
+
test/python/visualization/test_dag_drawer.py::TestDagDrawer::test_dag_drawer_no_register
+ # tiny image differences, sigh
+
test/python/visualization/test_gate_map.py::TestGateMap::test_plot_error_map_over_100_qubit
+ # TODO: failures from dill
+
test/python/circuit/test_parameters.py::TestParameters::test_transpiling_multiple_parameterized_circuits
+
test/python/compiler/test_transpiler.py::TestTranspile::test_delay_converts_expr_to_dt
+
test/python/compiler/test_transpiler.py::TestTranspile::test_transpile_two
+
test/python/transpiler/test_naming_transpiled_circuits.py::TestNamingTranspiledCircuits::test_multiple_circuits_name_list
+ )
+
+ local EPYTEST_IGNORE=(
+ # Breaks xdist
+ test/python/qasm2/test_parse_errors.py
+ test/python/transpiler/test_preset_passmanagers.py
+ )
+
+ rm -rf qiskit || die
+ # Run the Python test suite rather than everything under test/ which
+ # includes the 'randomized' suite. Upstream run that in a separate CI
job.
+ epytest test/python
+}
