commit: 7df8bfd860de36329ddab85381cb5c42a168cb27
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 26 10:23:02 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jul 26 10:25:06 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7df8bfd8
dev-python/setuptools: Remove old
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/setuptools/setuptools-80.9.0.ebuild | 130 -------------------------
1 file changed, 130 deletions(-)
diff --git a/dev-python/setuptools/setuptools-80.9.0.ebuild
b/dev-python/setuptools/setuptools-80.9.0.ebuild
deleted file mode 100644
index 26356f533d5e..000000000000
--- a/dev-python/setuptools/setuptools-80.9.0.ebuild
+++ /dev/null
@@ -1,130 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
-EAPI=8
-
-# please bump dev-python/ensurepip-setuptools along with this package!
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_TESTED=( python3_{11..14} pypy3_11 )
-PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_{13,14}t )
-PYTHON_REQ_USE="xml(+)"
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Collection of extensions to Distutils"
-HOMEPAGE="
- https://github.com/pypa/setuptools/
- https://pypi.org/project/setuptools/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv
~s390 sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
- dev-python/jaraco-collections[${PYTHON_USEDEP}]
- >=dev-python/jaraco-functools-4[${PYTHON_USEDEP}]
- >=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
- >=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
- >=dev-python/packaging-24.2[${PYTHON_USEDEP}]
- >=dev-python/platformdirs-4.2.2[${PYTHON_USEDEP}]
- >=dev-python/wheel-0.44.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
- ${RDEPEND}
- test? (
- $(python_gen_cond_dep '
- >=dev-python/build-1.0.3[${PYTHON_USEDEP}]
- >=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
- >=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
- >=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
- >=dev-python/jaraco-path-3.7.2[${PYTHON_USEDEP}]
- >=dev-python/jaraco-test-5.5[${PYTHON_USEDEP}]
- dev-python/pip[${PYTHON_USEDEP}]
- dev-python/pyproject-hooks[${PYTHON_USEDEP}]
- dev-python/pytest[${PYTHON_USEDEP}]
- >=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
- dev-python/pytest-subprocess[${PYTHON_USEDEP}]
- dev-python/pytest-timeout[${PYTHON_USEDEP}]
- dev-python/pytest-xdist[${PYTHON_USEDEP}]
- >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
- >=dev-python/virtualenv-20[${PYTHON_USEDEP}]
- ' "${PYTHON_TESTED[@]}")
- )
-"
-# setuptools-scm is here because installing plugins apparently breaks stuff at
-# runtime, so let's pull it early. See bug #663324.
-#
-# trove-classifiers are optionally used in validation, if they are
-# installed. Since we really oughtn't block them, let's always enforce
-# the newest version for the time being to avoid errors.
-# https://github.com/pypa/setuptools/issues/4459
-PDEPEND="
- dev-python/setuptools-scm[${PYTHON_USEDEP}]
- >=dev-python/trove-classifiers-2024.10.16[${PYTHON_USEDEP}]
-"
-
-src_prepare() {
- local PATCHES=(
- # TODO: remove this when we're 100% PEP517 mode
- "${FILESDIR}/setuptools-62.4.0-py-compile.patch"
- # https://github.com/abravalheri/validate-pyproject/pull/221
- "${FILESDIR}/setuptools-75.6.0-disable-trove-classifiers.patch"
- )
-
- distutils-r1_src_prepare
-
- # breaks tests
- sed -i -e '/--import-mode/d' pytest.ini || die
-
- # remove bundled dependencies
- rm -r */_vendor || die
-}
-
-python_test() {
- if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
- return
- fi
-
- local EPYTEST_DESELECT=(
- # network
- setuptools/tests/integration/test_pbr.py::test_pbr_integration
-
setuptools/tests/test_build_meta.py::test_legacy_editable_install
-
setuptools/tests/test_develop.py::TestNamespaces::test_namespace_package_importable
- setuptools/tests/test_distutils_adoption.py
- setuptools/tests/test_editable_install.py
-
setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
-
setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
- # TODO
-
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
-
setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
- # expects bundled deps in virtualenv
-
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
-
setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
- # fails if python-xlib is installed
-
setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
- # TODO, probably some random package
-
setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
- # broken by unbundling
-
setuptools/tests/test_setuptools.py::test_wheel_includes_vendored_metadata
- # fails on normalized metadata, perhaps different dep version?
-
setuptools/tests/test_build_meta.py::TestBuildMetaBackend::test_build_with_pyproject_config
- # TODO
-
setuptools/tests/test_sdist.py::test_sanity_check_setuptools_own_sdist
- # relies on -Werror
- setuptools/_static.py::setuptools._static.Dict
- setuptools/_static.py::setuptools._static.List
- setuptools/tests/test_bdist_egg.py::Test::test_bdist_egg
- # TODO
- setuptools/dist.py::setuptools.dist.Distribution._find_pattern
- )
-
- local EPYTEST_XDIST=1
- local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
- epytest -o tmp_path_retention_policy=all \
- -m "not uses_network" setuptools
-}
