[gentoo-commits] repo/gentoo:master commit in: app-eselect/eselect-repository/

[Michał Górny]

commit:     3a55533708d274ed2e27fd10c9f07cd67911737e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 15 07:03:38 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul 15 07:03:38 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3a555337

app-eselect/eselect-repository: Bump to 15

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 app-eselect/eselect-repository/Manifest            |  1 +
 .../eselect-repository-15.ebuild                   | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/app-eselect/eselect-repository/Manifest 
b/app-eselect/eselect-repository/Manifest
index 0893096b64d3..b017d7a870f4 100644
--- a/app-eselect/eselect-repository/Manifest
+++ b/app-eselect/eselect-repository/Manifest
@@ -1 +1,2 @@
 DIST eselect-repository-14.tar.gz 8954 BLAKE2B 
01cfe850a4ede31e28ef28c26093217691b1e77ac52c4fed3c2bffac9e066e7d298e34c88028fce996edcfb0f2efcc3799db7d70753e40455d455ad0dd68edf5
 SHA512 
dc5350aba4fe5b76b0d5cfdf267b34ea26f3d3e3c7ec3d523696fd2635a49f616297d2dc9efc6bb7ce2ebd9c87a4ad7f0f06f115da34c401ed6306e5be7ac687
+DIST eselect-repository-15.tar.gz 15622 BLAKE2B 
bbb8c525255d5cb62099449432b44295cfed1f95611424eedd3eae26261d51343016eee315eef3c06f06be0ed2fdf6724263e190046339df5a904840b483bd17
 SHA512 
15bdea99b172e1fe7e0a1fa82e8594764b0d4b5a31c79579596367bc7eebebdad520e4676b60d6ad6370460d277e8de2a4c99e13793a2b15731464b88af25efc

diff --git a/app-eselect/eselect-repository/eselect-repository-15.ebuild 
b/app-eselect/eselect-repository/eselect-repository-15.ebuild
new file mode 100644
index 000000000000..2956f611388b
--- /dev/null
+++ b/app-eselect/eselect-repository/eselect-repository-15.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+inherit python-single-r1
+
+DESCRIPTION="Manage repos.conf via eselect"
+HOMEPAGE="https://github.com/projg2/eselect-repository/";
+SRC_URI="
+       https://github.com/projg2/eselect-repository/archive/v${PV}.tar.gz
+               -> ${P}.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 
~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="+git mercurial test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       app-admin/eselect
+       $(python_gen_cond_dep '
+               dev-python/lxml[${PYTHON_USEDEP}]
+       ')
+       net-misc/wget
+       git? ( dev-vcs/git )
+       mercurial? ( dev-vcs/mercurial )
+"
+BDEPEND="
+       test? (
+               $(python_gen_cond_dep '
+                       dev-python/pytest[${PYTHON_USEDEP}]
+               ')
+       )
+"
+
+src_compile() {
+       MAKEARGS=(
+               PREFIX="${EPREFIX}/usr"
+               SYSCONFDIR="${EPREFIX}/etc"
+               SHAREDSTATEDIR="${EPREFIX}/var"
+               ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
+       )
+
+       emake "${MAKEARGS[@]}"
+       python_fix_shebang eselect-repo-helper
+}
+
+src_test() {
+       local EPYTEST_PLUGINS=()
+       epytest
+}
+
+src_install() {
+       emake "${MAKEARGS[@]}" DESTDIR="${D}" install
+       einstalldocs
+}