commit: 0f669fabb8c8e65e9a06a1b462687d5104fe5806
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 14 18:37:55 2025 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jul 14 18:56:53 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f669fab
app-misc/mosquitto: Version bump to 2.0.22
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
app-misc/mosquitto/Manifest | 1 +
app-misc/mosquitto/mosquitto-2.0.22.ebuild | 132 +++++++++++++++++++++++++++++
2 files changed, 133 insertions(+)
diff --git a/app-misc/mosquitto/Manifest b/app-misc/mosquitto/Manifest
index 827585ec4d18..14d3693844bb 100644
--- a/app-misc/mosquitto/Manifest
+++ b/app-misc/mosquitto/Manifest
@@ -1,2 +1,3 @@
DIST mosquitto-2.0.20.tar.gz 799972 BLAKE2B
fe1445ff6e2a6869ca911dbc556a2ea3d8826ddfd7dc1c46d6c409a320e58cbae4a3c62f02e3cad96cd2d09d30acd8667e1be2cd197211ca80de2ba782b7c7dc
SHA512
4c16ff0ad0e9c6fe5c65ec5a82bef123d9e6490f42658d646e1fad60f098530b7cbbd743460c52d4dec8bc27698c84a557bd539b35ac6c81444539822a544c4c
DIST mosquitto-2.0.21.tar.gz 804168 BLAKE2B
b8afd947dd05293e47d17e1f87186abd7e8719fdcf7e98b680e581bab3d8060e7d43b55421f9a477a797eb17c031523c8282e859f3ff216ded88e022f35e463e
SHA512
3acc093ef709c3f0f9d837abbb9e39e4e4ed60488c6180e2da733d65b19107f607c1fb89592d39a14faea531c8689227232e7cb13f3f58cb5ee43dad317c7cd6
+DIST mosquitto-2.0.22.tar.gz 805967 BLAKE2B
fb66fdc2513f954b8d207e326dbf9b69e8e89d9ac44894e89afea9278dbb99ffd1ee14cbdac5c1b7be71c1094df5a80887ef3eb0ca95211285e85c568dc8faee
SHA512
5aae399b308d8262a758a72064c613bfd6930e1a54f34939e30454d988c65c9d7c4c139ed70a016baa1264a0100a0c842c00e843ffe3ef83f90be440403e7482
diff --git a/app-misc/mosquitto/mosquitto-2.0.22.ebuild
b/app-misc/mosquitto/mosquitto-2.0.22.ebuild
new file mode 100644
index 000000000000..adf71d495fad
--- /dev/null
+++ b/app-misc/mosquitto/mosquitto-2.0.22.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit eapi9-ver python-any-r1 systemd toolchain-funcs
+
+DESCRIPTION="An Open Source MQTT v3 Broker"
+HOMEPAGE="https://mosquitto.org/ https://github.com/eclipse/mosquitto";
+SRC_URI="https://mosquitto.org/files/source/${P}.tar.gz";
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+bridge examples +persistence +srv ssl systemd tcpd test websockets"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="test? ( bridge )"
+
+RDEPEND="
+ acct-user/mosquitto
+ acct-group/mosquitto
+ dev-libs/cJSON
+ srv? ( net-dns/c-ares:= )
+ ssl? (
+ dev-libs/openssl:0=
+ )
+ systemd? ( sys-apps/systemd:= )
+ tcpd? ( sys-apps/tcp-wrappers )
+ websockets? ( net-libs/libwebsockets[lejp] )
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( dev-util/cunit )
+"
+BDEPEND="
+ test? (
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep 'dev-python/psutil[${PYTHON_USEDEP}]')
+ )
+"
+
+python_check_deps() {
+ python_has_version -b "dev-python/psutil[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use test && python_setup
+}
+
+_emake() {
+ local LIBDIR=$(get_libdir)
+ emake \
+ CC="$(tc-getCC)" \
+ CXX="$(tc-getCXX)" \
+ CLIENT_LDFLAGS="${LDFLAGS}" \
+ LIB_SUFFIX="${LIBDIR:3}" \
+ WITH_BRIDGE="$(usex bridge)" \
+ WITH_PERSISTENCE="$(usex persistence)" \
+ WITH_SRV="$(usex srv)" \
+ WITH_SYSTEMD="$(usex systemd)" \
+ WITH_TLS="$(usex ssl)" \
+ WITH_WEBSOCKETS="$(usex websockets)" \
+ WITH_WRAP="$(usex tcpd)" \
+ "$@"
+}
+
+src_prepare() {
+ default
+ if use persistence; then
+ sed -i -e "/^#autosave_interval/s|^#||" \
+ -e "s|^#persistence false$|persistence true|" \
+ -e "/^#persistence_file/s|^#||" \
+ -e "s|#persistence_location|persistence_location
/var/lib/mosquitto/|" \
+ mosquitto.conf || die
+ fi
+
+ # Remove failing tests
+ sed -i \
+ -e '/06-bridge-reconnect-local-out.py/d' \
+ test/broker/Makefile || die
+ sed -i \
+ -e '/02-subscribe-qos1-async2.test/d' \
+ test/lib/Makefile || die
+
+ # Extend test timeout to prevent spurious failures
+ sed -i -e 's/SUB_TIMEOUT=1/SUB_TIMEOUT=3/' \
+ test/client/test.sh || die
+
+ use test && python_fix_shebang test
+}
+
+src_compile() {
+ _emake
+}
+
+src_test() {
+ _emake test
+}
+
+src_install() {
+ _emake DESTDIR="${D}" prefix=/usr install
+ keepdir /var/lib/mosquitto
+ fowners mosquitto:mosquitto /var/lib/mosquitto
+ dodoc README.md CONTRIBUTING.md ChangeLog.txt
+ doinitd "${FILESDIR}"/mosquitto
+ insinto /etc/mosquitto
+ doins mosquitto.conf
+ insinto /usr/share/mosquitto
+ doins misc/letsencrypt/mosquitto-copy.sh
+ systemd_newunit "${FILESDIR}/mosquitto.notify.service" mosquitto.service
+
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ dodoc -r examples
+ fi
+}
+
+pkg_postinst() {
+ if ver_replacing -lt 2; then
+ elog
+ elog "Please read the migration guide at:"
+ elog "https://mosquitto.org/documentation/migrating-to-2-0/";
+ elog
+ elog "If you use Lets Encrypt TLS certificates, take note of"
+ elog "the changes required to run the daemon as the
unprivileged"
+ elog "mosquitto user. The mosquitto-copy.sh script has been"
+ elog "installed to /usr/share/mosquitto/ for your convenience."
+ elog
+ fi
+}
