commit: ce80079890b05559729e4211f4ad62a50441eaa4
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 13 03:15:10 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jul 13 03:15:10 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ce800798
dev-python/pipdeptree: Bump to 2.27.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pipdeptree/Manifest | 1 +
dev-python/pipdeptree/pipdeptree-2.27.0.ebuild | 57 ++++++++++++++++++++++++++
2 files changed, 58 insertions(+)
diff --git a/dev-python/pipdeptree/Manifest b/dev-python/pipdeptree/Manifest
index 5972ef69d2e7..3d352634f0ce 100644
--- a/dev-python/pipdeptree/Manifest
+++ b/dev-python/pipdeptree/Manifest
@@ -1,2 +1,3 @@
DIST pipdeptree-2.23.4.tar.gz 39945 BLAKE2B
6f1aaf4652b872a28712cf23fb06c26c9e36baf2c5c734b542d418d78081c19f567c730944fba33b43cf6ad612ecd54f37f625a81e88fc8bb68e3e56d76d9088
SHA512
3beeeceb11f842e5f337167b724354b43b01f972f83b0bac5168504483a079e15758206a8e141dc88e4810954630bff1b1cdec3e69aa2f981b9ec2896e40428d
DIST pipdeptree-2.26.1.tar.gz 41024 BLAKE2B
93121352931669bb343f156673ebff6cf3f7601da34f027aeaa3764f676a578ed1c5360e1a281c18ce07f870f20f594694cec0da1be8f836568400c9861c0b8a
SHA512
3cb0aa2a3d07a03aa62c0da9ff0d39496e4afe4f9216c2445c36d34b1f05f5bea5030e04d89aa27f5f41cb65092ded4d949a863bc2f223f1fbbe5fdcf379af62
+DIST pipdeptree-2.27.0.tar.gz 42423 BLAKE2B
1e6593bab1f0e61acbf7f0dd5b168f0afa5cf6c0bd1b49bbe92ec24d37c8051bef4a2a13944369a03a778099af78ac4a9b201c360aeb441f195c68d0126cfdc3
SHA512
4f7c5aeea24baa6a6031b456918897c17abd71ea46d661e54f21774ad90b70beb3fba50f44611e44beeadf1d9cddbc41fd0adea16a4da172a70bb3322876c297
diff --git a/dev-python/pipdeptree/pipdeptree-2.27.0.ebuild
b/dev-python/pipdeptree/pipdeptree-2.27.0.ebuild
new file mode 100644
index 000000000000..85e1def3741d
--- /dev/null
+++ b/dev-python/pipdeptree/pipdeptree-2.27.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Utility for displaying installed packages in a dependency tree"
+HOMEPAGE="
+ https://github.com/tox-dev/pipdeptree/
+ https://pypi.org/project/pipdeptree/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+ >=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+ >=dev-python/pip-23.1.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/hatch-vcs[${PYTHON_USEDEP}]
+ test? (
+ dev-python/graphviz[${PYTHON_USEDEP}]
+ <dev-python/virtualenv-21[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20.31.1[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # upstream lower bounds are meaningless
+ sed -i -e 's:>=[0-9.]*,\?::' pyproject.toml || die
+
+ find -name '*.py' -exec \
+ sed -i -e 's:pip[.]_vendor[.]::' {} + || die
+}
+
+python_test() {
+ # tests can fail if other packages are being merged simultaneously
+ epytest --reruns=5
+}
+
+pkg_postinst() {
+ optfeature \
+ "visualising the dependency graph with --graph-output" \
+ dev-python/graphviz
+}
