commit: ea792b65f3ec1c9fa116c571708077a5f78d7915
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 12 06:26:11 2025 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jul 12 06:26:11 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea792b65
dev-util/diffoscope: add 301
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-util/diffoscope/Manifest | 1 +
dev-util/diffoscope/diffoscope-301.ebuild | 143 ++++++++++++++++++++++++++++++
2 files changed, 144 insertions(+)
diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 1343d00bfeb0..0742dddd1af6 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -5,3 +5,4 @@ DIST diffoscope-297.tar.bz2 3157531 BLAKE2B
65bfdd327c2a7ed6dc2e55f88080c60e15f7
DIST diffoscope-298.tar.bz2 3156802 BLAKE2B
b3b008604f9df70dc62e58a2285aa2b42bd74b69101be4a412ad8d741ad2cb7ee557ab9088e8b8a6d1ddfcfae71f7ce946dd0b02964e75276db1fe180aa69235
SHA512
e5723928e782ba04ccf8cb009d6a8e30bd1998abc72e3b37e2a1489976ef68ed61a007500781b3907c19490f9c88200e163f5b0c8e6699d3b3f3993f1d81a513
DIST diffoscope-299.tar.bz2 3157091 BLAKE2B
76f2db1b9059e6715b8a03305920da2865f9d9e25ea6029867e471798de94c9072cc720268dd81f50037343e84e634e08829a9f5938756abf4b0c559536ea7c2
SHA512
932c51b8cf99e4a0270276ab9a70dc0a491c4d3b596c7478c3e650b2b1edff2f6d464949a1ae74650750c5221bebe4aae231f0e302f59019324bf2659056101e
DIST diffoscope-300.tar.bz2 3155652 BLAKE2B
b262978ae6c57dda7105c62470d424ca5331cb2193eb94cf4ebd5df5a6a28b3095d2fe07ffd63867b32a6435137a5108e73dbcd4b6cde2714a8bb3d6aa9d100d
SHA512
a540fd3c472e088d83a7f2dfb2c6f099df00c996839af245ef1da5caee714f63a2d8902daedb90618743a8478899188f517a4ea9fa646f3436803d51615574e5
+DIST diffoscope-301.tar.bz2 3156259 BLAKE2B
eb02b57ced856829545ddf34c3816c6395d11b66a12ec915e93ae04b867b361e4c63841104c6f7530b7a58be37c8646eb6c9ab18a8c156a15b237549486e1924
SHA512
b3e739b50eaf12f6c2892c0847b059b45047db1e8d8ed9c87ddc941480bdb9d994a57ab893969978a9bc713f8a624764e8e58d12353c35cc8963186614c9cad4
diff --git a/dev-util/diffoscope/diffoscope-301.ebuild
b/dev-util/diffoscope/diffoscope-301.ebuild
new file mode 100644
index 000000000000..fe95eb4abf68
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-301.ebuild
@@ -0,0 +1,143 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories
different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/";
+# We could use pypi, but upstream provide distribution tarballs, so let's use
those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2";
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ || (
+ dev-python/python-magic[${PYTHON_USEDEP}]
+ sys-apps/file[python,${PYTHON_USEDEP}]
+ )
+ dev-python/libarchive-c[${PYTHON_USEDEP}]
+ dev-python/distro[${PYTHON_USEDEP}]
+ dev-python/python-tlsh[${PYTHON_USEDEP}]
+ acl? ( sys-apps/acl )
+ binutils? ( sys-devel/binutils )
+ bzip2? ( app-arch/bzip2 )
+ libcaca? ( media-libs/libcaca )
+ colord? ( x11-misc/colord )
+ cpio? ( app-alternatives/cpio )
+ diff? ( sys-apps/diffutils )
+ docx? ( app-text/docx2txt )
+ dtc? ( sys-apps/dtc )
+ e2fsprogs? ( sys-fs/e2fsprogs )
+ file? ( sys-apps/file )
+ find? ( sys-apps/findutils )
+ gettext? ( sys-devel/gettext )
+ gif? ( media-libs/giflib )
+ gpg? ( app-crypt/gnupg )
+ haskell? ( dev-lang/ghc )
+ hdf5? ( sci-libs/hdf5 )
+ hex? ( app-editors/vim-core )
+ imagemagick? ( media-gfx/imagemagick )
+ iso? ( app-cdr/cdrtools )
+ java? ( virtual/jdk )
+ llvm? ( llvm-core/llvm )
+ lzma? ( app-arch/xz-utils )
+ mono? ( dev-lang/mono )
+ opendocument? ( app-text/odt2txt )
+ pascal? ( dev-lang/fpc )
+ pdf? (
+ app-text/pdftk
+ app-text/poppler
+ dev-python/pypdf[${PYTHON_USEDEP}]
+ )
+ postscript? ( app-text/ghostscript-gpl )
+ R? ( dev-lang/R )
+ rpm? ( app-arch/rpm )
+ sqlite? ( dev-db/sqlite:3 )
+ squashfs? ( sys-fs/squashfs-tools )
+ ssh? ( virtual/openssh )
+ tar? ( app-arch/tar )
+ tcpdump? ( net-analyzer/tcpdump )
+ zip? ( app-arch/unzip )
+ zlib? ( app-arch/gzip )
+ zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+ test? (
+ || (
+ >=app-arch/7zip-24.09[symlink(+)]
+ app-arch/p7zip
+ )
+ app-text/docx2txt
+ app-text/html2text
+ media-libs/libcaca
+ virtual/imagemagick-tools[jpeg]
+ )
+"
+
+EPYTEST_DESELECT=(
+ # Test seems to use different tarball
+ tests/test_presenters.py::test_text_proper_indentation
+
+ # Needs triage
+
tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+ tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+ tests/comparators/test_gif.py::test_has_visuals
+
+ # img2txt based failures, bug #797688
+ tests/comparators/test_ico_image.py::test_diff
+ tests/comparators/test_ico_image.py::test_diff_meta
+ tests/comparators/test_ico_image.py::test_diff_meta2
+ tests/comparators/test_ico_image.py::test_has_visuals
+ tests/comparators/test_jpeg_image.py::test_diff
+ tests/comparators/test_jpeg_image.py::test_compare_non_existing
+ tests/comparators/test_jpeg_image.py::test_diff_meta
+ tests/comparators/test_jpeg_image.py::test_has_visuals
+
+ # docx2txt based falures, bug #797688
+ tests/comparators/test_docx.py::test_diff
+
+ # Formatting
+ tests/test_source.py::test_code_is_black_clean
+
+ # Fails on ZFS
+ tests/test_main.py::test_non_unicode_filename
+
+ # Fails on (unreleased) LLVM 16 with minor difference
+ #tests/comparators/test_macho.py::test_llvm_diff
+ #tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+ case $(tc-get-ptr-size) in
+ 4)
+ EPYTEST_IGNORE+=(
+ # Needs fixing in Perl itself (bug #934443)
+ tests/comparators/test_epub.py
+ tests/comparators/test_zip.py
+ )
+ ;;
+ *)
+ ;;
+ esac
+
+ distutils-r1_src_test
+}
