commit: 7dfc265c493ed40863dcd691f28478b673343121
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 7 07:56:03 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jul 8 16:03:06 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7dfc265c
dev-libs/libjcat: add 0.2.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-libs/libjcat/Manifest | 1 +
dev-libs/libjcat/libjcat-0.2.3.ebuild | 82 +++++++++++++++++++++++++++++++++++
2 files changed, 83 insertions(+)
diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index 741a02ca8e2a..dfdfb18ac5f4 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
DIST libjcat-0.2.2.tar.xz 66128 BLAKE2B
30e855ec626616adf8326832dbb6e5c9266ffd41d14d1ef2a230f72e0a339d4c8ed83adacd0253faf242b065736dca7f25bd4ce04d30605998d39cacf01beac0
SHA512
91d4d9761e7de3ae312d9ef7b92fbbb82be262cdc4259ee9dad7abef8912abb047b2db51886b3d323565cb2d9a3175a56161b4879d27b36d4d318ad4419ab594
+DIST libjcat-0.2.3.tar.xz 66188 BLAKE2B
200cac29d355cce54a4d722bcdd5dcd88e2aea59c31fb43a37cf4a7272cd7d996acafa3e4e70e15fdd59174be158b9c5134acef6a722504f97835095f63eb274
SHA512
ff4627c3917b10eb5acce0c0c2f583f6cebe8d9c7501ff3cbb9a8b419db62761d6b82674786cbfa00fe66d30a7699bc87c37e76648e45884a97523d68ac6ae15
diff --git a/dev-libs/libjcat/libjcat-0.2.3.ebuild
b/dev-libs/libjcat/libjcat-0.2.3.ebuild
new file mode 100644
index 000000000000..cf0c88037dc1
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.2.3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+PYTHON_REQ_USE="xml(+)"
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat";
+SRC_URI="https://github.com/hughsie/libjcat/releases/download/${PV}/${P}.tar.xz";
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~loong ppc64 ~riscv x86"
+IUSE="+ed25519 +gpg gtk-doc +introspection +man +pkcs7 test vala"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-libs/glib:2
+ dev-libs/json-glib:=
+ ed25519? ( net-libs/gnutls:= )
+ gpg? (
+ app-crypt/gpgme:=
+ dev-libs/libgpg-error
+ )
+ introspection? ( dev-libs/gobject-introspection:= )
+ pkcs7? ( net-libs/gnutls:= )
+ vala? ( dev-lang/vala:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+ $(python_gen_any_dep '
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ ')
+ gtk-doc? ( dev-util/gtk-doc )
+ man? ( sys-apps/help2man )
+ test? ( net-libs/gnutls[tools] )
+"
+
+python_check_deps() {
+ python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use vala && vala_setup
+}
+
+src_prepare() {
+ xdg_environment_reset
+ default
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use ed25519)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use gpg)
+ $(meson_use introspection)
+ $(meson_use man)
+ $(meson_use pkcs7)
+ $(meson_use test tests)
+ $(meson_use vala vapi)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if use test; then
+ # Preventing tests from being installed in the first place is a
moving target,
+ # just axe them all afterwards.
+ rm -rf \
+ "${ED}"/usr/libexec/installed-tests \
+ "${ED}"/usr/share/installed-tests \
+ || die
+ fi
+}
