commit: 85ab073d153049703320ac71c6b0065cd4147658
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Jul 6 15:08:29 2025 +0000
Commit: David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Sun Jul 6 15:10:55 2025 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=85ab073d
phosh-base/phosh-shell: add 0.48.0
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
phosh-base/phosh-shell/Manifest | 2 +
phosh-base/phosh-shell/phosh-shell-0.48.0.ebuild | 182 +++++++++++++++++++++++
2 files changed, 184 insertions(+)
diff --git a/phosh-base/phosh-shell/Manifest b/phosh-base/phosh-shell/Manifest
index 3e28adace9..f3837d262a 100644
--- a/phosh-base/phosh-shell/Manifest
+++ b/phosh-base/phosh-shell/Manifest
@@ -2,3 +2,5 @@ DIST phosh-0.42.0.tar.xz 940212 BLAKE2B
91935d095102320823283968861563b93d1c5581
DIST phosh-0.42.0.tar.xz.asc 833 BLAKE2B
9dc5771e5650bc30b8b72b048eb5cccc137152be1e51afc30dab82569890a18aab932defcc6ca4a3bc8ce31af9b9659c56b792119b042c2f6490b1a9eb8e828c
SHA512
8d5dd2eb60ae369da18fd79de8a696835f7ce94a39c20a597bfa9ed2a4ed44af606123f994a6040d96c6a7b52a28418eb4e066e64858b8f8c15c2e2395f08b50
DIST phosh-0.47.0.tar.xz 1021352 BLAKE2B
f48766e0f981e4ceda53302af9935e54db66b12be2169852473320f1e39d82d7cbd56aa38d59803b5115fbd4bcd10560020be28714441f41e93175806086cdcb
SHA512
19c150d28921b383269e4c95d353b7ea69e62cc4075a7a1e1523aa0977b347898d16df7d88861e5d029469a881623e15673ee270c3c514db123aec683ec8194d
DIST phosh-0.47.0.tar.xz.asc 833 BLAKE2B
682bd67276f3f95eea1ab352195c38e292ca5175b0ac2415ae01c1acf597e8248477800a295842c99c1608043cccff1331604e0575f57a0dc70bb46183f29ffc
SHA512
89293648f3b66db822e9bf368938b14253a6a00d7e051d5d238434a6b77f3eba0931ff9c6ed94b5f57c17f4dbf3dee1e7ebc20a1f186c3e8e82549cb4bcb8268
+DIST phosh-0.48.0.tar.xz 1025860 BLAKE2B
e09746ad13714599e3f5e59fa7ab1a24aad816d175c2f37edac25daab7619c3101167b31b0789c536f48f5b7d866dd2b0dbd2e904ad99f21bc3e2b4f9a35c5b2
SHA512
7d689b29d39aae0937fdcf22c8fe5267de6174487d75df67a3d71e7cb23b765ce138e8c7769256cb0ca006241692ec8376f5119f1c576c2ea2edc437abcda335
+DIST phosh-0.48.0.tar.xz.asc 833 BLAKE2B
b7c30f692f1db539d0175f996f0cf24a6e51067424fee3f106f3be9c5bbe9ef1f7ff2f413c9e2d8f7dd17ad89972e5e14bd6124995498d1aa1efec5f4d2059c3
SHA512
00d8a62f60cd9d0f2b4453cdf0a3422342c012693763d7f7d3f0500b80701e5c169d65b6f4d54220621e9dda9af5260dcb260b9fa1f1e6f8cb7a43e819b354ba
diff --git a/phosh-base/phosh-shell/phosh-shell-0.48.0.ebuild
b/phosh-base/phosh-shell/phosh-shell-0.48.0.ebuild
new file mode 100644
index 0000000000..4bd936b34b
--- /dev/null
+++ b/phosh-base/phosh-shell/phosh-shell-0.48.0.ebuild
@@ -0,0 +1,182 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson pam systemd toolchain-funcs vala verify-sig
virtualx xdg
+
+MY_PN="${PN%-shell}"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Pure Wayland shell for mobile devices"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phosh/";
+SRC_URI="https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz
+ verify-sig? (
https://sources.phosh.mobi/releases/${MY_PN}/${MY_P}.tar.xz.asc )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="CC0-1.0 CC-BY-SA-4.0 GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc introspection +lockscreen-plugins man +plugins systemd test
test-full vala"
+REQUIRED_USE="
+ gtk-doc? ( introspection )
+ lockscreen-plugins? ( plugins )
+ test? ( plugins lockscreen-plugins )
+ vala? ( introspection )
+"
+
+COMMON_DEPEND="
+ >=app-crypt/gcr-3.7.5:0=[introspection?]
+ app-crypt/libsecret
+ >=dev-libs/appstream-1.0.0:=
+ >=dev-libs/feedbackd-0.7.0
+ dev-libs/fribidi
+ >=dev-libs/glib-2.76:2
+ dev-libs/gmobile
+ dev-libs/libgudev:=
+ dev-libs/libical:=
+ >=dev-libs/wayland-1.14
+ >=gnome-base/gnome-desktop-3.26:3=[introspection?]
+ >=gnome-base/gsettings-desktop-schemas-47
+ >=gnome-extra/evolution-data-server-3.33.1:=
+ >=gui-libs/libhandy-1.1.90:1[introspection?]
+ media-libs/libpulse[glib]
+ media-sound/callaudiod
+ >=net-libs/libsoup-3.6:3.0
+ net-misc/modemmanager:=
+ >=net-misc/networkmanager-1.14[introspection?]
+ >=net-wireless/gnome-bluetooth-46.0:3=[introspection?]
+ sys-apps/dbus
+ >=sys-auth/polkit-0.122
+ sys-libs/pam
+ >=sys-power/upower-0.99.1:=
+ x11-libs/cairo
+ x11-libs/gdk-pixbuf:2
+ x11-libs/pango
+ >=x11-libs/gtk+-3.22:3[introspection?,wayland]
+ systemd? ( >=sys-apps/systemd-241:= )
+ !systemd? ( >=sys-auth/elogind-241 )
+ plugins? (
+ >=gui-libs/gtk-4.12:4
+ >=gui-libs/libadwaita-1.5:1
+ lockscreen-plugins? (
+ app-text/evince:=
+ )
+ )
+"
+RUNTIME_DEPEND="
+ gnome-base/gnome-shell
+ virtual/freedesktop-icon-theme
+ x11-themes/gnome-themes-standard
+"
+
+DEPEND="
+ ${COMMON_DEPEND:?}
+ >=dev-libs/wayland-protocols-1.12
+ test-full? ( ${RUNTIME_DEPEND:?} )
+ vala? (
+ $(vala_depend)
+ >=net-misc/networkmanager-1.14[vala]
+ )
+"
+RDEPEND="
+ ${COMMON_DEPEND:?}
+ ${RUNTIME_DEPEND:?}
+ systemd? ( sys-libs/libcap )
+"
+BDEPEND="
+ dev-libs/glib:2
+ dev-libs/libxml2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/wayland-scanner
+ sys-devel/gettext
+ virtual/pkgconfig
+ gtk-doc? ( dev-util/gi-docgen )
+ introspection? ( dev-libs/gobject-introspection )
+ man? ( dev-python/docutils )
+ test-full? ( >=gui-wm/phoc-0.45.0 )
+ verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+# https://gitlab.gnome.org/World/Phosh/phosh/-/issues/1240
+# https://gitlab.gnome.org/World/Phosh/phosh/-/merge_requests/1733
+RESTRICT="test"
+
+src_prepare() {
+ use vala && vala_setup
+ default
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dcompositor="${EPREFIX}"/usr/bin/phoc
+ -Dtools=true
+ $(meson_use gtk-doc gtk_doc)
+ $(meson_use introspection)
+ $(meson_use introspection bindings-lib)
+ $(meson_use lockscreen-plugins)
+ $(meson_use plugins quick-setting-plugins)
+ $(meson_use man)
+ $(meson_use test tests)
+ $(meson_feature test-full phoc_tests)
+ $(meson_use vala vapi)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ my_src_test() {
+ local -x LC_ALL="C.UTF-8"
+ local -x WLR_RENDERER="pixman"
+ local -x PHOSH_TEST_PHOC_INI="${T}/phoc.ini"
+
+ meson_src_test --suite unit || return 1
+ if use test-full; then
+ meson_src_test --suite integration --timeout-multiplier
2 || return 1
+ fi
+ }
+
+ # Xwayland breaks "phosh:integration / shell", pollutes /tmp
+ cat data/phoc.ini - > "${T}"/phoc.ini <<- EOF || die
+ [core]
+ xwayland=false
+ EOF
+
+ virtx my_src_test
+}
+
+src_install() {
+ meson_src_install
+ find "${ED}/usr/$(get_libdir)" -name '*.a' -delete || die
+
+ pamd_mimic system-local-login phosh auth account session
+ systemd_douserunit data/phosh.service
+
+ if use gtk-doc; then
+ mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+ mv "${ED}"/usr/share/doc/${MY_PN}-${SLOT}
"${ED}"/usr/share/gtk-doc/html/ || die
+ fi
+}
+
+phosh_giomodule_cache_update() {
+ local plugins_dir
+ plugins_dir=$("$(tc-getPKG_CONFIG)" --variable=lockscreen_plugins_dir
phosh-plugins) || return 1
+
+ ebegin "Updating GIO modules cache"
+ gio-querymodules "${plugins_dir}"
+ eend $?
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+ phosh_giomodule_cache_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+ phosh_giomodule_cache_update
+}
