commit: 8526939f4ee6093806730cebf2913f16930fc5cd
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 14 08:38:04 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun 14 08:54:05 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8526939f
dev-python/authlib: Bump to 1.6.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/authlib/Manifest | 1 +
dev-python/authlib/authlib-1.6.0.ebuild | 75 +++++++++++++++++++++++++++++++++
2 files changed, 76 insertions(+)
diff --git a/dev-python/authlib/Manifest b/dev-python/authlib/Manifest
index 2211b6b7a705..c150944a2e88 100644
--- a/dev-python/authlib/Manifest
+++ b/dev-python/authlib/Manifest
@@ -1 +1,2 @@
DIST authlib-1.5.2.gh.tar.gz 331162 BLAKE2B
e4f25f621398ca85b2d1e526aaa24a6ed07512afe85023646764682fb49353b7ae4052405747161b041e5873404ec88396b589463fe27be1495ef4fea9150a49
SHA512
ac396e3ea13637aa612f5893687b9dc51988addf719c304007ec6966ac36f843e82090ebe109d454d8da8766eeb50661a0968ff7f596b00541aaf592df919892
+DIST authlib-1.6.0.gh.tar.gz 341039 BLAKE2B
26faa75dbbaf6ca7350dbcd04d01d38bbbc3ee9f096437bee03be4180ed4b82560707b1ee403abf52eea4f6b53f760e5ad9bd8357cc227ed41b571ad9ff815a6
SHA512
5ff057fe9699b192218bf0863635230137fe1cb86129ba545b468f2df4491b475e81b6c296efd9965cfdb2cfc782f46bd49f93b1b222b5ce1f0b49145ef9ef45
diff --git a/dev-python/authlib/authlib-1.6.0.ebuild
b/dev-python/authlib/authlib-1.6.0.ebuild
new file mode 100644
index 000000000000..d43af1f05b2e
--- /dev/null
+++ b/dev-python/authlib/authlib-1.6.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and
clients"
+HOMEPAGE="
+ https://authlib.org/
+ https://github.com/authlib/authlib/
+ https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+ https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="django flask jose test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ django? (
+ dev-python/django[${PYTHON_USEDEP}]
+ )
+ flask? (
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+ )
+ jose? (
+ >=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ test? (
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/anyio[${PYTHON_USEDEP}]
+ dev-python/cachelib[${PYTHON_USEDEP}]
+ dev-python/django[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+ dev-python/httpx[${PYTHON_USEDEP}]
+ >=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/starlette[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # convert from pycryptodomex to pycryptodome
+ sed -i -e 's:from Cryptodome:from Crypto:' \
+ authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x DJANGO_SETTINGS_MODULE=tests.clients.test_django.settings
+ epytest -p asyncio tests/{core,jose,clients,flask}
+
+ # TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded
yet.
+ #local -x DJANGO_SETTINGS_MODULE=tests.django.settings
+ #epytest -p asyncio tests/django
+}
