commit: 33222b674fde3842187ffad7b3cdec026c23741a
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 9 21:19:17 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jun 11 15:29:50 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33222b67
kde-frameworks/knotifications: Drop slightly stupid IUSE dbus
...since dev-qt/qtdbus:5 was always required unconditionally anyway,
which means we get rid of the last dev-libs/libdbusmenu-qt revdep.
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
.../knotifications-5.116.0-r2.ebuild | 47 ++++++++++++++++++++++
1 file changed, 47 insertions(+)
diff --git a/kde-frameworks/knotifications/knotifications-5.116.0-r2.ebuild
b/kde-frameworks/knotifications/knotifications-5.116.0-r2.ebuild
new file mode 100644
index 000000000000..a06932a9d299
--- /dev/null
+++ b/kde-frameworks/knotifications/knotifications-5.116.0-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Framework for notifying the user of an event"
+
+LICENSE="LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="qml speech X"
+
+RDEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ =kde-frameworks/kconfig-${PVCUT}*:5
+ =kde-frameworks/kcoreaddons-${PVCUT}*:5
+ =kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
+ media-libs/libcanberra
+ qml? ( >=dev-qt/qtdeclarative-${QTMIN}:5 )
+ speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+ X? (
+ >=dev-qt/qtx11extras-${QTMIN}:5
+ x11-libs/libX11
+ x11-libs/libXtst
+ )
+"
+DEPEND="${RDEPEND}
+ X? ( x11-base/xorg-proto )
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_DISABLE_FIND_PACKAGE_dbusmenu-qt5=ON
+ $(cmake_use_find_package qml Qt5Qml)
+ $(cmake_use_find_package speech Qt5TextToSpeech)
+ -DWITHOUT_X11=$(usex !X)
+ )
+
+ ecm_src_configure
+}
