commit: e04fb099881d6722ede7c966d3d1c5a110905b86
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 5 02:58:41 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun 5 03:42:15 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e04fb099
dev-python/django: Bump to 5.2.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-5.2.2.ebuild | 98 +++++++++++++++++++++++++++++++++++
2 files changed, 100 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index a7e19789a3d9..202ecc01f4bc 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,7 +1,9 @@
DIST Django-4.2.21.checksum.txt 2545 BLAKE2B
177d4a2f07fcd27c39eeddb56ee9219ddba6b8a570680d9dcee39fc400dbd6d3ae430f663d7759b52f8ccc7581d3d66e3168a7807bc8c206c7eddfe7c726248d
SHA512
e94d767c774cd2909297f07ec2069d60161fbf27323fe2e321fd24ca12b49ef5883d2c6f4ee7271dd131aa8e97bbf0b421323f5ad30bafd90040fb1a7e6ef013
DIST Django-5.1.9.checksum.txt 2535 BLAKE2B
12a08519b2f179df7435597233adc9fc281ad5eacb5b6a88c6ce5b701989c8ade84c7a82bc81f8934d10d1dfac978b967aec5b791b614c7b7d01948359599820
SHA512
6034ce27fe17e8e7216701a2d465264d13a8a25f5d3cd13c5c97e8c65c77f267d78ef9f99beb0c32494f2e6e72b61f39554073f275a8435e8dd11403788aa96d
DIST Django-5.2.1.checksum.txt 2535 BLAKE2B
e839f319f2845909cf1141f91ffa4817f41d7b43976daebdd7728b82d03bd82a1abedbe76de39c6107547ae92a0b05a817880d319202c27ecee48f1bf43519f9
SHA512
8a158d21fb94de396c39391766c603de5159783df88cd8bbe53c1352b7f48718092dcfaa1521fadc3fa3efa18129bed7347de84a43649a921343abdd783ae005
+DIST Django-5.2.2.checksum.txt 2536 BLAKE2B
2f90934e9ed1fb7527648b7e06978fd520ed09e4d7cebe7aa09b9c2ef95c5779070760c0c877f7d682f5c6b4b56ee054a5c7f34ed4c772bc4d5d8911349a7deb
SHA512
6a68c066486a5db7eb9757a38832dd51760f9daf16ffd0b545fcc44259c552a2ca4ea06b140a599a0212c1f9334657efaaf6f6d62ade10acc9c49c3ce25097bd
DIST django-4.2.17-pypy3.patch.xz 5900 BLAKE2B
2a564fc31d8e2f3def5a532d3bca1a4426a496c659192f602d659e0c1a5f5882978baedb384cc3b67fda8c836513ce43aece80db1528c8e8b6e9ca420f7572ce
SHA512
9c9d935aff6db7230a26931b5e7f5f94f3b5ff4fc8f7d4201178571de9d9c7929a0e1e558cc2d9b54b8ee91f85819a5680d24fad6251620515a4a020e3b2d66d
DIST django-4.2.21.tar.gz 10424638 BLAKE2B
c76170139e0b8926911d19a9b2319d85bcc577ebd36f55e80d5543da115baf31c7935eace893e8673ab338d97680d5f6f4e35bacc20a168188af363799c7bd83
SHA512
762201e56fff658b90d715545ba52420682f5382ebcb38602f25b921c82bce3877dcc54d07578c3b5bfcef62d5ce7836f19b7d638bb3230a5ca4987cc6e70f8e
DIST django-5.1.9.tar.gz 10710887 BLAKE2B
b6caa00ef55d904209c0c20548963ccc91368d6a36395432fc86809b9fa41f4d8cce3122600983ca49593feb1b06fb4da72b5664ce418d3ee62d9aca98ebbe26
SHA512
f3fe34326e2fa4d35af26198f5839a7ad7bc433a659971528c0d7ba35c5d9e0300c9307114ad1eeaf242f6148ef2dbc48998752a0c68f80f9fbf5b8d32ddca2e
DIST django-5.2.1.tar.gz 10818735 BLAKE2B
583f78402534157d665a48a1569554ad31f0637c335d206f8dad384860971f27868184cfe0750cdc03d39879c736f88aace2d65ac8f25e60a16b8489fe51d5cf
SHA512
b97fc3221f2bcb499e2f55ea5fa8da61da9062266255a31e8d0a54afb7a41ea049dbe4b370ad7e8ca3b5105ab1d5a15f1fe3e48af4251590d27bc032fef17d25
+DIST django-5.2.2.tar.gz 10827542 BLAKE2B
188e4290236371c1fca73a2485897afd8e06f631900dcad298b2062d88e1405b958dd8bc77994eb0f32b59f61fe1565d6c0150f9bc76632924e23294afb9861a
SHA512
b4d5be87bd0daf68df76e2f79781b72dc7cbe372148edd83aa1ab9ffbbda8785ee85e63309a06ea454d233ce23972ae51213680dcdd9824177cef8c3285ec439
diff --git a/dev-python/django/django-5.2.2.ebuild
b/dev-python/django/django-5.2.2.ebuild
new file mode 100644
index 000000000000..0ee247e36495
--- /dev/null
+++ b/dev-python/django/django-5.2.2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc
~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ <dev-python/asgiref-4[${PYTHON_USEDEP}]
+ >=dev-python/asgiref-3.8.1[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+ sys-libs/timezone-data
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ >=dev-python/docutils-0.19[${PYTHON_USEDEP}]
+ >=dev-python/jinja2-2.11.0[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ >=dev-python/selenium-4.8.0[${PYTHON_USEDEP}]
+ >=dev-python/tblib-1.5.0[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/django-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+ -v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:0
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+}
