commit: 84cb8051f577a93ed129e4b38132c254ffc48552
Author: Eli Schwartz <eschwartz <AT> gentoo <DOT> org>
AuthorDate: Wed May 21 14:53:49 2025 +0000
Commit: Eli Schwartz <eschwartz <AT> gentoo <DOT> org>
CommitDate: Sun May 25 08:33:49 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84cb8051
dev-python/apsw: install manpage
Signed-off-by: Eli Schwartz <eschwartz <AT> gentoo.org>
dev-python/apsw/apsw-3.49.1.0-r1.ebuild | 53 +++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
diff --git a/dev-python/apsw/apsw-3.49.1.0-r1.ebuild
b/dev-python/apsw/apsw-3.49.1.0-r1.ebuild
new file mode 100644
index 000000000000..f7360a89573d
--- /dev/null
+++ b/dev-python/apsw/apsw-3.49.1.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="
+ https://github.com/rogerbinns/apsw/
+ https://pypi.org/project/apsw/
+"
+SRC_URI="
+ https://github.com/rogerbinns/apsw/releases/download/${PV}/${P}.zip
+"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc"
+
+DEPEND="
+ >=dev-db/sqlite-${PV%.*}:3
+"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="
+ app-arch/unzip
+"
+
+src_configure() {
+ cat >> setup.apsw <<-EOF || die
+ [build_ext]
+ use_system_sqlite_config=True
+ EOF
+}
+
+python_test() {
+ esetup.py build_test_extension
+ cd "${T}" || die
+ "${EPYTHON}" -m apsw.tests -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+ doman man/apsw.1
+ use doc && local HTML_DOCS=( doc/. )
+ distutils-r1_python_install_all
+}
