commit: 7c9dc4d3556cd365ff85c2ac2ade2cb393b42355
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun May 11 02:18:11 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May 11 02:22:17 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c9dc4d3
dev-python/astroid: Bump to 3.3.10
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/astroid/Manifest | 1 +
dev-python/astroid/astroid-3.3.10.ebuild | 97 ++++++++++++++++++++++++++++++++
2 files changed, 98 insertions(+)
diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index a5a59dc2ac25..7a909bfb0c34 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1 +1,2 @@
+DIST astroid-3.3.10.gh.tar.gz 467911 BLAKE2B
da2e62ff056298bd0dc7aed3a9ab5af25968a2343a5339d409a2d03f0043cbe6024e1440332c797f3645db4b836f54b1a7ea2dbd09f3d49ee765a19d0bd0d15c
SHA512
bec58f47f26a56f3700a6f10add2b90c018a2127b35036e1e4fc1d6c41fb35b67362195c506affba9ddf8ea120993e17adb562b799f1ee45622c79def4547e84
DIST astroid-3.3.9.gh.tar.gz 467796 BLAKE2B
6bca213d71de9599cb9102d4aa7f48f7df2b050875e9e566202e9ee700fd309064453a1b4df10d930abb1b4b32b9085ca1a6a569c68ab56c811d1fc51e3cba68
SHA512
c868f2b0da0c52cf827dd5c9e228f814fe307592eb9378968773d336ff412cd8186c826bd4b61e1329ef31e4efd9489d691d3db8a23d09b925354b2973cce943
diff --git a/dev-python/astroid/astroid-3.3.10.ebuild
b/dev-python/astroid/astroid-3.3.10.ebuild
new file mode 100644
index 000000000000..1e1536ca3844
--- /dev/null
+++ b/dev-python/astroid/astroid-3.3.10.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+ https://github.com/pylint-dev/astroid/
+ https://pypi.org/project/astroid/
+"
+SRC_URI="
+ https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+
+# dev-python/regex isn't available for pypy
+BDEPEND="
+ dev-python/setuptools-scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/attrs[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/regex[${PYTHON_USEDEP}]
+ ' 'python*')
+ )
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # https://bugs.gentoo.org/951713
+ sed -i -e '/license-files.*Keep in sync/d' pyproject.toml || die
+}
+
+python_test() {
+ local EPYTEST_IGNORE=()
+ local EPYTEST_DESELECT=(
+ # no clue why they're broken
+
tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+ tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+ # pydantic-2?
+ tests/brain/test_dataclasses.py::test_pydantic_field
+ # requires urllib3 with bundled six (skipped with urllib3>=2)
+
tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+ # hangs
+ tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+ # TODO
+
tests/test_builder.py::BuilderTest::test_data_build_error_filename
+ # numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
+
tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
+
tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
+
tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
+
tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
+
tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
+
tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
+
tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
+ )
+
+ if ! has_version "dev-python/mypy[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/test_raw_building.py
+ )
+ fi
+
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+
tests/test_transforms.py::TestTransforms::test_transform_aborted_if_recursion_limited
+ )
+ ;;
+ python3.13)
+ EPYTEST_DESELECT+=(
+ # changes in py3.13.0b4
+ #
https://github.com/pylint-dev/astroid/issues/2478
+
tests/test_nodes.py::AsStringTest::test_f_strings
+
tests/test_nodes_lineno.py::TestLinenoColOffset::test_end_lineno_string
+ )
+ ;;
+ esac
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
