commit: 5f2a342dd7738cfced169f99390395c924f52e76
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu May 8 17:33:28 2025 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Thu May 8 17:34:54 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f2a342d
net-wireless/iwd: add 3.8
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-wireless/iwd/Manifest | 1 +
net-wireless/iwd/iwd-3.8.ebuild | 167 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 168 insertions(+)
diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index 8880a776e0b7..273f3a02f237 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -3,3 +3,4 @@ DIST iwd-3.3.tar.xz 1103272 BLAKE2B
dd3f54f1a15bdef49da8ffe8359cd579b51da6762f2c
DIST iwd-3.4.tar.xz 1111100 BLAKE2B
b6400db7dd416bbb42318dc55cadda3121f467aee939a085651d326170f27d177f40c930fcae1acada4b9166ec0aafbb07bba1c4d03aba26c6d1a8113a1637f7
SHA512
7ff456306a92398e0ab5aae8ae2abdb13d86c9ad282fd4f24db89aee4fc32b347f3bf332564dfcc1b41030531761c9c9c16d751fa17158545574bc3eeb9e4cb7
DIST iwd-3.6.tar.xz 1115264 BLAKE2B
fbf461cddb88f9c0d9201b50d8f86053f54df33260759d7f957804f6b27e5fcf7422db23e561f994b4fe99ad92c5f17f071db7fe7a4bba11573c175a6c6c54fc
SHA512
6a306900ec3b3076335861c66a526a58796cc696f535e9fe047e641548d2747cbd846d02e100396228a2536d09e329b5bfb8db3c1149313d73c2c2c1f3d1c9a9
DIST iwd-3.7.tar.xz 1116172 BLAKE2B
880e7bc0be2e033762418d946d6a800d653d1edd5d17e3c5a9ea3f378f98155b201243aa610afbddefccc84b899fc6cf12c047b8c5a0329d4b9ae7d8e509b8e5
SHA512
24aee7dca446f8b7bb275270ec207181181cd0656d23dd571a71eea53c2d0fe5c06444266050784ef95fbfa7a18cbd610d5c0f5b9cbbb23d4591e48150af2c9a
+DIST iwd-3.8.tar.xz 1116376 BLAKE2B
fdbc5b7a777f80dde1a9642bc32e7f7c6c14d2cd8d0a106bd57a60b808566acfb23ef31c57f577c58c00fc6b546a8bef86af3bfea8dc069bc7b7238b50f57e03
SHA512
5bc136be8d97918baa7581753cafda9a781e09871b869e9dc77df36de0e9a83e17373f03724210b8436a727f22e5d33c7eec3b10cd2501fcee363a551d2122cd
diff --git a/net-wireless/iwd/iwd-3.8.ebuild b/net-wireless/iwd/iwd-3.8.ebuild
new file mode 100644
index 000000000000..e953b4e5dad1
--- /dev/null
+++ b/net-wireless/iwd/iwd-3.8.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit flag-o-matic linux-info systemd
+
+#Set this variable to the required external ell version
+ELL_REQ="0.77"
+
+if [[ ${PV} == *9999* ]]; then
+ inherit autotools git-r3
+
IWD_EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git";
+ ELL_EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git";
+else
+
SRC_URI="https://mirrors.edge.kernel.org/pub/linux/network/wireless/${P}.tar.xz";
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc
~x86"
+ MYRST2MAN="RST2MAN=:"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/";
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client cpu_flags_x86_aes cpu_flags_x86_ssse3 +monitor ofono selinux
standalone systemd wired"
+
+DEPEND="
+ sys-apps/dbus
+ client? ( sys-libs/readline:0= )
+"
+
+[[ -z "${ELL_REQ}" ]] || DEPEND+=" ~dev-libs/ell-${ELL_REQ}"
+
+RDEPEND="
+ ${DEPEND}
+ acct-group/netdev
+ net-wireless/wireless-regdb
+ selinux? ( sec-policy/selinux-networkmanager )
+ standalone? (
+ systemd? ( sys-apps/systemd )
+ !systemd? ( virtual/resolvconf )
+ )
+"
+
+BDEPEND="
+ virtual/pkgconfig
+"
+
+[[ ${PV} == *9999* ]] && BDEPEND+=" dev-python/docutils"
+
+pkg_setup() {
+ CONFIG_CHECK="
+ ~ASYMMETRIC_KEY_TYPE
+ ~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+ ~CFG80211
+ ~CRYPTO_AES
+ ~CRYPTO_CBC
+ ~CRYPTO_CMAC
+ ~CRYPTO_DES
+ ~CRYPTO_ECB
+ ~CRYPTO_HMAC
+ ~CRYPTO_MD4
+ ~CRYPTO_MD5
+ ~CRYPTO_RSA
+ ~CRYPTO_SHA1
+ ~CRYPTO_SHA256
+ ~CRYPTO_SHA512
+ ~CRYPTO_USER_API_HASH
+ ~CRYPTO_USER_API_SKCIPHER
+ ~KEY_DH_OPERATIONS
+ ~PKCS7_MESSAGE_PARSER
+ ~RFKILL
+ ~X509_CERTIFICATE_PARSER
+ "
+
+ if use amd64;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_DES3_EDE_X86_64"
+ WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable
for increased performance"
+ fi
+
+ if use cpu_flags_x86_aes;then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+ WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for
increased performance"
+ fi
+
+ if use cpu_flags_x86_ssse3 && use amd64; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3
~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+ WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for
increased performance"
+ WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for
increased performance"
+ fi
+
+ if use kernel_linux && kernel_is -ge 4 20; then
+ CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999* ]] ; then
+ EGIT_REPO_URI=${IWD_EGIT_REPO_URI} git-r3_src_unpack
+ EGIT_REPO_URI=${ELL_EGIT_REPO_URI}
EGIT_CHECKOUT_DIR=${WORKDIR}/ell git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == *9999* ]] ; then
+ eautoreconf
+ fi
+
+ sed -e "s:Exec=/bin/false:Exec=${EPREFIX}/usr/libexec/iwd:g" -i
src/net.connman.iwd.service || die
+}
+
+src_configure() {
+ append-cflags "-fsigned-char"
+ local myeconfargs=(
+ --sysconfdir="${EPREFIX}"/etc/iwd
--localstatedir="${EPREFIX}"/var
+ "$(use_enable client)"
+ "$(use_enable monitor)"
+ "$(use_enable ofono)"
+ "$(use_enable wired)"
+ --enable-systemd-service
+ --with-systemd-unitdir="$(systemd_get_systemunitdir)"
+ --with-systemd-modloaddir="${EPREFIX}/usr/lib/modules-load.d"
+ --with-systemd-networkdir="$(systemd_get_utildir)/network"
+ )
+ [[ ${PV} == *9999* ]] || myeconfargs+=(--enable-external-ell)
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake "${MYRST2MAN}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" "${MYRST2MAN}" install
+ keepdir "/var/lib/${PN}"
+
+ newinitd "${FILESDIR}/iwd.initd-r1" iwd
+
+ if use wired;then
+ newinitd "${FILESDIR}/ead.initd" ead
+ fi
+
+ if [[ ${PV} == *9999* ]] ; then
+ exeinto /usr/share/iwd/scripts/
+ doexe test/*
+ fi
+
+ if use standalone ; then
+ local iwdconf="${ED}/etc/iwd/main.conf"
+ dodir /etc/iwd
+ cat << EOF > "${iwdconf}"
+[General]
+EnableNetworkConfiguration=true
+
+[Network]
+NameResolvingService=$(usex systemd systemd resolvconf)
+EOF
+ dodir /etc/conf.d
+ echo "rc_provide=\"net\"" > "${ED}"/etc/conf.d/iwd
+ fi
+}
