[gentoo-commits] repo/gentoo:master commit in: kde-frameworks/kwallet/

[Andreas Sturmlechner]

commit:     cd9a58f3f9edf7cb632b055ec4d5ef634b91b0d9
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 26 13:44:43 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Apr 28 17:12:54 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd9a58f3

kde-frameworks/kwallet: Drop IUSE kf6compat, prepare for qca[qt5] cleanup

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kwallet/kwallet-5.116.0-r2.ebuild | 53 ++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/kde-frameworks/kwallet/kwallet-5.116.0-r2.ebuild 
b/kde-frameworks/kwallet/kwallet-5.116.0-r2.ebuild
new file mode 100644
index 000000000000..752ffb558b80
--- /dev/null
+++ b/kde-frameworks/kwallet/kwallet-5.116.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature
+
+DESCRIPTION="Framework providing desktop-wide storage for passwords"
+
+LICENSE="LGPL-2+"
+KEYWORDS="amd64 arm64 ~loong ppc64 ~riscv ~x86"
+IUSE="+man"
+
+DEPEND="
+       >=app-crypt/qca-2.3.9:2[qt5(-)]
+       dev-libs/libgcrypt:0=
+       >=dev-qt/qtdbus-${QTMIN}:5
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtwidgets-${QTMIN}:5
+       =kde-frameworks/kconfig-${PVCUT}*:5
+       =kde-frameworks/kconfigwidgets-${PVCUT}*:5
+       =kde-frameworks/kcoreaddons-${PVCUT}*:5
+       =kde-frameworks/kdbusaddons-${PVCUT}*:5
+       =kde-frameworks/ki18n-${PVCUT}*:5
+       =kde-frameworks/knotifications-${PVCUT}*:5
+       =kde-frameworks/kservice-${PVCUT}*:5
+       =kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+       =kde-frameworks/kwindowsystem-${PVCUT}*:5[X]
+"
+RDEPEND="${DEPEND}
+       kde-frameworks/kwallet:6
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
+
+src_configure() {
+       local mycmakeargs=(
+               -DBUILD_KWALLETD=OFF
+               -DBUILD_KWALLET_QUERY=OFF
+               $(cmake_use_find_package man KF5DocTools)
+       )
+       ecm_src_configure
+}
+
+pkg_postinst() {
+       if [[ -z "${REPLACING_VERSIONS}" ]]; then
+               optfeature "Auto-unlocking after Plasma login" 
"kde-plasma/kwallet-pam"
+               optfeature "KWallet management" "kde-apps/kwalletmanager"
+               elog "For more information, read 
https://wiki.gentoo.org/wiki/KDE#KWallet";
+       fi
+       ecm_pkg_postinst
+}