commit: b3c641a86103cd786fa4fba50a952005aaf63cba
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 26 20:14:56 2025 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Apr 28 17:12:53 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b3c641a8
kde-frameworks/kguiaddons: Relax blocker against kguiaddons:5[-kf6compat]
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
.../kguiaddons/kguiaddons-6.13.0-r1.ebuild | 55 ++++++++++++++++++++++
1 file changed, 55 insertions(+)
diff --git a/kde-frameworks/kguiaddons/kguiaddons-6.13.0-r1.ebuild
b/kde-frameworks/kguiaddons/kguiaddons-6.13.0-r1.ebuild
new file mode 100644
index 000000000000..ea7ec895198a
--- /dev/null
+++ b/kde-frameworks/kguiaddons/kguiaddons-6.13.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_PYTHON_BINDINGS="off"
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org xdg
+
+DESCRIPTION="Framework providing assorted high-level user interface components"
+
+LICENSE="LGPL-2+"
+KEYWORDS="amd64 arm64 ~loong ppc64 ~riscv ~x86"
+IUSE="dbus wayland X"
+
+# slot op: includes qpa/qplatformnativeinterface.h
+COMMON_DEPEND="
+ >=dev-qt/qtbase-${QTMIN}:6[dbus?,gui]
+ >=dev-qt/qtdeclarative-${QTMIN}:6
+ wayland? (
+ dev-libs/wayland
+ >=dev-qt/qtbase-${QTMIN}:6=[wayland]
+ >=dev-qt/qtwayland-${QTMIN}:6
+ )
+ X? (
+ >=dev-qt/qtbase-${QTMIN}:6[X]
+ x11-libs/libX11
+ )
+"
+DEPEND="${COMMON_DEPEND}
+ wayland? ( >=dev-libs/plasma-wayland-protocols-1.15.0 )
+ X? (
+ x11-base/xorg-proto
+ x11-libs/libxcb
+ )
+"
+RDEPEND="${COMMON_DEPEND}
+ !<kde-frameworks/kguiaddons-5.116.0-r2:5[-kf6compat(-)]
+"
+BDEPEND="
+ wayland? (
+ >=dev-qt/qtwayland-${QTMIN}:6
+ dev-util/wayland-scanner
+ )
+"
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_GEO_SCHEME_HANDLER=ON
+ -DUSE_DBUS=$(usex dbus)
+ -DWITH_WAYLAND=$(usex wayland)
+ -DWITH_X11=$(usex X)
+ )
+ ecm_src_configure
+}
