commit: ce4956709a11528269daca826a95a53fc8f01637
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 29 05:19:05 2025 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Mar 29 05:19:05 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ce495670
dev-python/pydantic: Bump to 2.11.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pydantic/Manifest | 1 +
dev-python/pydantic/pydantic-2.11.1.ebuild | 71 ++++++++++++++++++++++++++++++
2 files changed, 72 insertions(+)
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index b5f90e3602d2..76c530899fa5 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1,3 +1,4 @@
DIST pydantic-2.10.6.tar.gz 761681 BLAKE2B
1ddb057cd40f50d09dc870aae937bc4d5d41529601c26b84bbd5223d75adca43e14e779ef40ef88dbeab3dc66ae960b662a3244ffa38bf8718d6f9d50b966aed
SHA512
69c5cdfb9047875497cf2ac0107f0aaa8d1d91a354d514277e913cc13081e1a76f72a154b50339c95240c82d2a262f4b8dcf71c1e5762449bd344054dba449ce
DIST pydantic-2.11.0.tar.gz 782184 BLAKE2B
44c0e4ee4ef99ffaa285b38c3876d4e36a587b527df988013e0390150d3e9e667ffcb35fe6a56db13cdb7518416ecf99371f653630481020f94ca0edb8b8e110
SHA512
9447508502a5530c28701af47b17f074e068ee69496b3f4b63e3e3d224a1cb22220429077c225ba6e5ffe3b8e0373c9a390182ac786f724013545a823f4abc74
DIST pydantic-2.11.0b2.tar.gz 776762 BLAKE2B
6632a96d46b71519527bacffe99e07c0a548b03bfda1980dbab005bf7bc2169b89140ba894eb1fab1216b5ad9155ade13ded32606ed5a781549c59da949db6ea
SHA512
8bcdf95a1a90a4b7b7c42e338f16ee3268e2bdf5d7c1c72df6ab81db82a79a273c858103068cfc13a3728b1f3c720faf4118e6ae2a4fd762f12eb7dea36b7d5f
+DIST pydantic-2.11.1.tar.gz 782817 BLAKE2B
9fb685ad6a3cb2b107f35f43e119cc92cef0b09a9abffca2c57548d325a77060a3ad752411ce06fd8221470a5b1605340ecd468b8e985ed7013fb972d825673e
SHA512
cf71c91b362f67255c428c142f5b5a1cad6259f319e5ad41ae434db95caa9f16e392f878a9ddd89de5221c34413e47e76645c7068085bd585dbca1083818bee5
diff --git a/dev-python/pydantic/pydantic-2.11.1.ebuild
b/dev-python/pydantic/pydantic-2.11.1.ebuild
new file mode 100644
index 000000000000..0ee182f8982a
--- /dev/null
+++ b/dev-python/pydantic/pydantic-2.11.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+ https://github.com/pydantic/pydantic/
+ https://pypi.org/project/pydantic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/annotated-types-0.6.0[${PYTHON_USEDEP}]
+ ~dev-python/pydantic-core-2.33.0[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.12.2[${PYTHON_USEDEP}]
+ >=dev-python/typing-inspection-0.4.0[${PYTHON_USEDEP}]
+ dev-python/tzdata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
+ test? (
+ $(python_gen_cond_dep '
+ dev-python/cloudpickle[${PYTHON_USEDEP}]
+ ' 'python3*' pypy3)
+ dev-python/dirty-equals[${PYTHON_USEDEP}]
+ >=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/faker-18.13.0[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ sed -i -e '/benchmark/d' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # -Werror, sigh
+ tests/test_types_typeddict.py::test_readonly_qualifier_warning
+ )
+ local EPYTEST_IGNORE=(
+ # require pytest-examples
+ tests/test_docs.py
+ # benchmarks
+ tests/benchmarks
+ )
+
+ if ! has_version "dev-python/cloudpickle[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/test_pickle.py
+ )
+ fi
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p pytest_mock
+}
