commit: 21ce791588b517329bbba78b6049083f76d3bd64
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 24 07:00:49 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 24 11:17:10 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=21ce7915
dev-python/pylint: Bump to 3.3.3
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.3.3.ebuild | 92 +++++++++++++++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index a99be4e1b2e3..5d5c2b127178 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1 +1,2 @@
DIST pylint-3.3.2.gh.tar.gz 1454335 BLAKE2B
dba68aead7d2babe885d4a94220e61ddc6c5759bd9703d2bbeb1c7d1c68b6bebce7cbe6d7b0cc18a7c8cfe32b7e0cc6be929e021e7a9223ae31839185c07558f
SHA512
48f57bc74a47c8658cad9ede6bb8540077c72fc6b3e8d9d401ddd1d43daaf547637ad253af885ac503a79aa31c30de1b4b302c4d4001a18b68e064e505975980
+DIST pylint-3.3.3.gh.tar.gz 1454469 BLAKE2B
e44ee31359421c560f89eee04215c222ce6b9f1fdce97750fe118cdb011f69c2a44a0a5a870787f4cd0c647650a78bc5a01dc327d8aaa8976f89e298f26596a1
SHA512
2267e7684b464255d03366bfd7988ac74222c08903a8b93bd5bc64181b12d1386c56ebb6dd79eb5b3f6c1a71bbc60282bf388fafc37a3e2c271286bc07ff2ac7
diff --git a/dev-python/pylint/pylint-3.3.3.ebuild
b/dev-python/pylint/pylint-3.3.3.ebuild
new file mode 100644
index 000000000000..7344911a46a3
--- /dev/null
+++ b/dev-python/pylint/pylint-3.3.3.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.4[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.3.8[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/gitpython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ >=dev-python/pytest-8.3[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/gitpython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
