Jakub Jelinek wrote on 2006-11-20:
> I think you should use -pthread instead of -lpthread here (and put it into
> CFLAGS too temporarily), to make it more portable, or try all of nothing,
> -pthread and -lpthread, i.e. add a for loop trying to compile and run the
> program 3 times.
Here's a revised patch that does this: first find out which flags are
needed to build a program that uses pthread_create(), then see whether
libc actually supports __thread.
I've verified that this patch causes the configuration to print
checking whether the target supports thread-local storage... no
in the situation of bug #28468.
2006-12-17 Bruno Haible <[EMAIL PROTECTED]>
* config/tls.m4 (GCC_CHECK_TLS): Also check whether the libc supports
TLS via __thread.
--- config/tls.m4.bak 2006-12-04 12:13:07.000000000 +0100
+++ config/tls.m4 2006-12-17 18:02:30.000000000 +0100
@@ -13,9 +13,60 @@
AC_RUN_IFELSE([__thread int a; int b; int main() { return a = b; }],
[have_tls=yes], [have_tls=no],[]),
[have_tls=yes])
- LDFLAGS="$save_LDFLAGS"],
+ LDFLAGS="$save_LDFLAGS"
+ if test $have_tls = yes; then
+ dnl So far, the binutils and the compiler support TLS.
+ dnl Also check whether the libc supports TLS, i.e. whether a variable
+ dnl with __thread linkage has a different address in different threads.
+ dnl First, find the thread_CFLAGS necessary for linking a program that
+ dnl calls pthread_create.
+ save_CFLAGS="$CFLAGS"
+ thread_CFLAGS=failed
+ for flag in '' '-pthread' '-lpthread'; do
+ CFLAGS="$flag $save_CFLAGS"
+ AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM(
+ [#include <pthread.h>
+ void *g(void *d) { return NULL; }],
+ [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
+ [thread_CFLAGS="$flag"])
+ if test "X$thread_CFLAGS" != Xfailed; then
+ break
+ fi
+ done
+ CFLAGS="$save_CFLAGS"
+ if test "X$thread_CFLAGS" != Xfailed; then
+ CFLAGS="$thread_CFLAGS $save_CFLAGS"
+ AC_RUN_IFELSE(
+ [AC_LANG_PROGRAM(
+ [#include <pthread.h>
+ __thread int a;
+ static int *a_in_other_thread;
+ static void *
+ thread_func (void *arg)
+ {
+ a_in_other_thread = &a;
+ return (void *)0;
+ }],
+ [pthread_t thread;
+ void *thread_retval;
+ int *a_in_main_thread;
+ if (pthread_create (&thread, (pthread_attr_t *)0,
+ thread_func, (void *)0))
+ return 2;
+ a_in_main_thread = &a;
+ if (pthread_join (thread, &thread_retval))
+ return 3;
+ return (a_in_other_thread == a_in_main_thread);])],
+ [have_tls=yes], [have_tls=no])
+ CFLAGS="$save_CFLAGS"
+ fi
+ fi],
[have_tls=no],
- [AC_COMPILE_IFELSE([__thread int foo;], [have_tls=yes], [have_tls=no])]
+ [dnl This is the cross-compiling case. Assume libc supports TLS if the
+ dnl binutils and the compiler do.
+ AC_COMPILE_IFELSE([__thread int foo;], [have_tls=yes], [have_tls=no])
+ ]
)])
if test "$enable_tls $have_tls" = "yes yes"; then
AC_DEFINE(HAVE_TLS, 1,
